%%HP: T(3)A(D)F(.);
DIR
  CLOSE
    \<< 0 '\GSDIS' STO
0 'AREA' STO 0 'C'
STO DAT VARS PURGE
UPDIR STCORD LEG
MISC
    \>>
  ADJ
    \<< RECT 0 'AREA'
STO DAT SE SN \->V2
"P." STD C 1 - +
OBJ\-> - \GSDIS / P.0 1
C 1 -
      FOR count
"P." count + OBJ\->
DUP 3 ROLLD SWAP -
DUP ABS 4 PICK * +
DUP "P." count 1 -
+ OBJ\-> DUP ROT +
UPDIR "P." count +
OBJ\-> DAT STO V\-> ROT
V\-> SWAP 2 / 4 ROLL
+ * UPDIR AREA +
'AREA' STO DAT DROP
      NEXT DROP2 1
C 1 -
      FOR count DAT
"P." STD count +
OBJ\-> DUP "P." count
1 - + OBJ\-> - V\-> R\->P
SWAP 127 CHR DUP +
DUP + DUP
"CORRECTED DATA" +
SWAP + "
Leg " +
count + "  Brg " +
SWAP DMS +
"
      Dist " +
SWAP 3 FIX + " m" +
"

Point " + STD
count +
"
Corr. E    " + 3
FIX SWAP V\-> 3 ROLLD
+ "
Corr. N    " +
SWAP + CLLCD 1 DISP
3 FREEZE 0 WAIT
DROP
      NEXT UPDIR
      IF 2 FC?
      THEN
"   ADJUSTED AREA  
  
    "
1 FIX AREA ABS +
" m" + 178 CHR +
CLLCD 1 DISP 3
FREEZE 0 WAIT DROP
      END 2 CF
    \>>
  DAT
    DIR
    END
  STCORD
    \<< 127 CHR DUP +
DUP + DUP
"START  CO-ORDS" +
SWAP + {
":E :
:N :" { 1 0 }
} INPUT OBJ\-> DUP2
DUP2 'SN' STO 'SE'
STO 'N' STO 'E' STO
\->V2 DAT 'P.0' STO
UPDIR
    \>>
  LEG
    \<< DEG 1 CF SE
SN
      DO C 1 + 'C'
STO
        IFERR "Pt."
STD C 1 - + " E  "
+ 3 FIX E + "
Pt."
+ STD C 1 - +
" N  " + 3 FIX N +
{
":Bearing :
:Distance:"
{ 1 0 } } INPUT
OBJ\-> DUP \GSDIS +
'\GSDIS' STO P\->R OVER
2 / 5 PICK + OVER *
AREA + 'AREA' STO
ROT + 'N' STO + 'E'
STO STD E N \->V2
"P." C + DAT OBJ\->
STO UPDIR E N
        THEN 1 SF
CLEAR
        END
      UNTIL 1 FS?
      END 1 CF
    \>>
  MISC
    \<< 2 CF
      IFERR 127 CHR
DUP + DUP + DUP
"END COORD DATA" +
SWAP +
"
(Hit ENTER if none)"
+ { ":E :
:N :" { 1
0 } } INPUT OBJ\->
'SN' STO 'SE' STO 2
SF
      THEN CLEAR
      END SN N - SE
E - DUP2 DUP2 2 / E
+ SWAP * AREA +
'AREA' STO SWAP R\->P
DUP 5 ROLLD SWAP
127 CHR DUP + DUP +
DUP
"MISCLOSE  DATA" +
SWAP +
"
Bearing    " + 4
FIX SWAP DMS +
"
Distance   " + 3
FIX SWAP + " m" +
"
\GDE         " +
SWAP +
"
\GDN         " +
SWAP +
"
Proportion 1:" +
\GSDIS ROT / 0 RND
STD +
      IF 2 FC?
      THEN
"
Unadj.Area " + 1
FIX AREA ABS + " m"
+ 178 CHR +
      END CLLCD 1
DISP 3 FREEZE 0
WAIT DROP
    \>>
  P\->R
    \<< DEG SWAP HMS\->
CYLIN \->V2 RECT V\->
SWAP
    \>>
  R\->P
    \<< DEG SWAP RECT
\->V2 CYLIN V\-> DUP
      IF 0 <
      THEN 360 +
      END \->HMS SWAP
RECT
    \>>
  DMS
    \<< DM 0 RND DUP
      IF 10 <
      THEN "0" SWAP
+
      END 34 CHR +
+ +
    \>>
  DM
    \<< STD DUP IP
176 CHR + SWAP ABS
FP 100 * DUP IP DUP
      IF 10 <
      THEN "0" SWAP
+
      END 39 CHR +
SWAP FP 100 *
    \>>
  SE 0
  SN 0
  E 0
  N 0
  \GSDIS 0
  C 0
  AREA 0
END
