%%HP: T(3)A(D)F(.);  
DIR
  CURV
    \<< { R.\Gh AL.\Gh
TL.\Gh { } { } MAIN }
TMENU
"Select known
combination"
CLLCD 6 DISP 3
FREEZE HALT
    \>>
  R.\Gh
    \<< DEG "" {
":Brg 1 :
:Brg 2 :
:Radius:"
{ 1 0 } } INPUT
OBJ\-> DTAG SWAP 3
PICK HMS- HMS\-> TBRG 
ROT HMS\->
\-> \<-r \<-\Gd
\<-b1   \<< CCRV
      \>>
    \>>
  AL.\Gh
    \<< DEG "" {
":Brg 1 :
:Brg 2 :
:Arc L.:"
{ 1 0 } } INPUT
OBJ\-> DTAG SWAP 3
PICK HMS- HMS\-> TBRG SWAP
OVER D\->R / SWAP 
ROT HMS\-> \->
 \<-r \<-\Gd  \<-b1
      \<< CCRV
      \>>
    \>>
  TL.\Gh
    \<< DEG "" {
":Brg 1 :
:Brg 2 :
:Tan.L.:"
{ 1 0 } } INPUT
OBJ\-> DTAG SWAP 3
PICK HMS- HMS\-> TBRG SWAP
OVER 2 / TAN / SWAP
ROT HMS\->
\-> \<-r \<-\Gd \<-b1 
      \<< CCRV
      \>>
    \>>
  TBRG
    \<< DUP
      IF 180 >
      THEN 360 SWAP
- NEG
      END DUP
      IF -180 <
      THEN 360 +
      END
    \>>
  CCRV
    \<< \<-\Gd 2 / DUP
DUP SIN SWAP COS *
SWAP D\->R SWAP - \<-r
SQ * \<-\Gd 2 / SIN 2 *
\<-r * \<-\Gd 2 / \<-b1 +
T360 \<-\Gd 2 / TAN \<-r
* \<-\Gd D\->R \<-r *
"******CURVE DATA*****
Radius     "
\<-r ABS 3 FIX +
"
Arc Length " +
SWAP ABS +
"
Tangent L. " +
SWAP ABS +
"
Chord Brg. " +
SWAP DMS +
"
Chord Dist." +
SWAP ABS 3 FIX +
"
Seg. Area  " +
SWAP ABS 1 FIX +
" m\178" + CLLCD 
1 DISP 3 FREEZE
    \>>
  T360
    \<< DUP
      IF 0 <
      THEN 360 +
      END DUP
      IF 360 \>=
      THEN 360 -
      END
    \>>
  DMS
    \<< STD \->HMS DUP
ABS IP OVER
      IF 0 <
      THEN "-" SWAP
+
      END "\^o" +
SWAP ABS DUP FP 100
* IP DUP
      IF 10 <
      THEN "0" SWAP
+
      END "'" +
SWAP 100 * FP 100 *
0 RND
STD
      DUP
      IF 10 <
      THEN "0" SWAP
+
      END 34 CHR +
+ +
    \>>
END
