%%HP: T(3)A(D)F(.);
DIR
  DRUG.EXE
    \<< CLLCD
"Finished 11/19/98
By Brian Sennello"
6 DISP
"-------DRUGWARS-------"
1 DISP
"         V1.11" 2
DISP REP CLLCD
"CHOOSE GAME" {
"NEW" "LOAD" } 1
CHOOSE
      IF 0 ==
      THEN HOME
KILL
      END 1 MENU
      IF "NEW" ==
      THEN RESET
REV
      ELSE LOAD
      END
    \>>
  INFO
"Object: buy drugs 
at a low price, sell
at a high price. Bust
up some people on the
way. Escape the cops.
Get $1,000,000 to 
win. Time: 1 month
Troubleshooting:
Push CST, or type
DRUG.EXE (to restart)
  IF YOU LIKE THIS
GAME, OR WOULD LIKE 
SOME OF MY OTHER 
GAMES, E-MAIL ME AT
bhrian@hotmail.com
HAVE FUN!"
  LOAD
    \<<
"SAVE CURRENT GAME?"
{ "YES" "NO" } 2
CHOOSE
      IF 0 ==
      THEN KILL
      END
      IF "YES" ==
      THEN SAVE
      END GAMS VARS
      IF { } ==
      THEN
"NO SAVED GAMES"
MSGBOX UPDIR KILL
      END
"LOAD WHICH GAME?"
VARS 1 CHOOSE DROP
RCL UPDIR EVAL
'MON' STO 'POK' STO
'PUSED' STO 'PL'
STO 'PS' STO 'PW'
STO 'PA' STO 'PH'
STO 'PC' STO 'LOC'
STO 'TCT' STO 'W'
STO 'HP' STO 'D'
STO 'PK' STO 'DBT'
STO 'ACCT' STO
    \>>
  SAVE
    \<< ACCT DBT PK D
HP W TCT LOC PC PH
PA PW PS PL PUSED
POK MON 17 \->LIST
"SAVE AS" "" INPUT
OBJ\-> GAMS STO UPDIR
"SAVE COMPLETE"
MSGBOX
    \>>
  OTHER
    \<< CLLCD
"DO WHAT?" { "BANK"
"BUST"
"SEE LOAN SHARK"
"SAVE" "LOAD" "NEW"
"QUIT" } 4 CHOOSE
      IF 1 ==
      THEN \-> D
        \<<
          IF D
"SEE LOAN SHARK" ==
          THEN LOAN
          ELSE
            IF D
"QUIT" ==
            THEN
SCOR 2 MENU HOME
            ELSE
              IF D
"NEW" ==
              THEN
RESET
              ELSE
D OBJ\->
              END
            END
          END
        \>>
      END
    \>>
  RESET
    \<< 1 'D' STO
RANPR { 0 0 0 0 0 0
} 'TCT' STO
"NOB HILL" 'LOC'
STO 50 'POK' STO 0
{ PD WD W PK PUSED
F ACCT } STO 2000
'MON' STO 20 'HP'
STO 2000 'DBT' STO
    \>>
  PRICE
    \<< "COCAINE: "
PC + 1 DISP 1
FREEZE "HEROIN:  "
PH + 2 DISP 2
FREEZE "ACID:    "
PA + 3 DISP 3
FREEZE "WEED:    "
PW + 4 DISP 4
FREEZE "SPEED:   "
PS + 5 DISP 5
FREEZE "LUDES:   "
PL + "    DAY " + D
+ 6 DISP 6 FREEZE
"WALLET   " MON + 7
DISP 7 FREEZE
    \>>
  COAT
    \<< 1 6
      FOR N TCT N
GET
      NEXT
"LUDES: " SWAP +
"    WEAPONS:" + W
+ 6 DISP 6 FREEZE
"SPEED: " SWAP +
"   DAY " D + + 5
DISP 5 FREEZE
"WEED: " SWAP +
"   HEALTH: " HP +
+ 4 DISP 4 FREEZE
"ACID: " SWAP +
"  " + LOC + 3 DISP
3 FREEZE "HEROIN: "
SWAP + 2 DISP 2
FREEZE "COCAINE: "
SWAP + 1 DISP 1
FREEZE "EMPTY: "
POK PUSED - + 7
DISP 7 FREEZE
    \>>
  BUY
    \<< "BUY WHAT?" {
"COCAINE" "HEROIN"
"ACID" "WEED"
"SPEED" "LUDES" } 1
CHOOSE
      IF 0 ==
      THEN KILL
      END \-> B
      \<< B HEAD "P"
SWAP + OBJ\-> 'PD'
STO
      \>>
"YOU CAN BUY " MON
PD / FLOOR +
" UNITS
YOU CAN HOLD "
+ POK PUSED - +
" UNITS" + MSGBOX
      IF MON PD / 1
<
      THEN KILL
      END
"BUY HOW MANY?" ""
INPUT OBJ\-> \-> BH
      \<<
        IF BH PD *
MON >
        THEN
"NOT ENOUGH MONEY"
MSGBOX
        ELSE MON BH
PD * - 'MON' STO
          IF BH POK
PUSED - >
          THEN
"NOT ENOUGH SPACE"
MSGBOX BH PD * MON
+ 'MON' STO
          ELSE
PUSED BH + 'PUSED'
STO
            IF PC
PD ==
            THEN 1
'WD' STO
            END
            IF PH
PD ==
            THEN 2
'WD' STO
            END
            IF PA
PD ==
            THEN 3
'WD' STO
            END
            IF PW
PD ==
            THEN 4
'WD' STO
            END
            IF PS
PD ==
            THEN 5
'WD' STO
            END
            IF PL
PD ==
            THEN 6
'WD' STO
            END TCT
TCT WD GET BH + WD
SWAP PUT 'TCT' STO
          END
        END
      \>>
    \>>
  SELL
    \<< "SELL WHAT?"
{ "COCAINE"
"HEROIN" "ACID"
"WEED" "SPEED"
"LUDES" } 1 CHOOSE
      IF 0 ==
      THEN KILL
      END HEAD "P"
SWAP + OBJ\-> 'PD'
STO
      IF PC PD ==
      THEN 1 'WD'
STO
      END
      IF PH PD ==
      THEN 2 'WD'
STO
      END
      IF PA PD ==
      THEN 3 'WD'
STO
      END
      IF PW PD ==
      THEN 4 'WD'
STO
      END
      IF PS PD ==
      THEN 5 'WD'
STO
      END
      IF PL PD ==
      THEN 6 'WD'
STO
      END TCT WD
GET \-> ND
      \<< "YOU HAVE "
ND + "
UNITS" +
MSGBOX
        IF ND 0 ==
        THEN KILL
        END
"SELL HOW MANY?" ""
INPUT OBJ\-> \-> SH
        \<<
          IF SH ND
>
          THEN
"YOU DON'T HAVE THAT MANY"
MSGBOX
          ELSE SH
PD * 'MON' STO+ TCT
TCT WD GET SH - WD
SWAP PUT 'TCT' STO
PUSED SH - 'PUSED'
STO
          END
        \>>
      \>>
    \>>
  JET
    \<< CLLCD LOC 1
DISP 1 FREEZE
"GO WHERE?" {
"NOB HILL"
"GG PARK"
"MARINA DIST"
"CHINATOWN"
"CANDLESTICK "
"NOWHERE" "QUIT" }
1 CHOOSE
      IF 1 ==
      THEN \-> L
        \<<
          IF L LOC
==
          THEN
"YOU'RE ALREADY
AT "
LOC + "!" + MSGBOX
KILL
          END
          IF L
"QUIT" ==
          THEN HOME
2 MENU KILL
          END
          IF L
"NOWHERE" ==
          THEN KILL
          ELSE L
'LOC' STO CLLCD
"BART..." 3 DISP
RANPR D 1 + 'D' STO
ACCT 1.05 * 'ACCT'
STO DBT 1.05 *
'DBT' STO
            IF MON
ACCT + 1000000 > F
"*" \=/ AND
            THEN
SCOR
            END
            IF D 32
==
            THEN
"YOUR TIME IS UP"
MSGBOX "YOU HAD $
"
MON ACCT + + MSGBOX
SCOR
            END REV
          END
        \>>
      END LOC 1
DISP 1 FREEZE
    \>>
  REP
    \<< KEY
      WHILE 0 ==
      REPEAT KEY
      END DROP
    \>>
  BANK
    \<<
      IF LOC HEAD
"N" \=/
      THEN
"THE BANK IS AT
NOB HILL."
MSGBOX KILL
      END CLLCD
ACCT IP 'ACCT' STO
"ACCOUNT: $" ACCT +
1 DISP "WALLET: $"
MON + 7 DISP 7
FREEZE "BANK" {
"DEPOSIT"
"WITHDRAW" "LEAVE"
} 1 CHOOSE DROP
HEAD \-> DW
      \<<
        IF DW "D"
==
        THEN
"DEPOSIT HOW MUCH?"
"" INPUT OBJ\-> DUP
          IF MON >
          THEN
"DON'T HAVE 
THAT MUCH"
MSGBOX DROP
          ELSE DUP
NEG 'MON' STO+
'ACCT' STO+
          END
        END
        IF DW "W"
==
        THEN
"WITHDRAW HOW MUCH?"
"" INPUT OBJ\-> DUP
          IF ACCT >
          THEN
"DON'T HAVE THAT MUCH"
MSGBOX DROP
          ELSE DUP
NEG 'ACCT' STO+
'MON' STO+
          END
        END
        IF DW "L" \=/
        THEN BANK
        END
      \>>
    \>>
  BUST
    \<< "BUST WHO?" {
"COP"
"RIVAL DEALER"
"LAWYER" "SKINHEAD"
} 1 CHOOSE
      IF 0 ==
      THEN KILL
      END HEAD RAND
5 * CEIL \-> WHO N
      \<<
        IF WHO "L"
\=/ N 1 == AND
        THEN
"HE PULLS OUT A
GUN..."
MSGBOX
          IF W 2 >
          THEN
"...AND YOU
PULL OUT "
W + MSGBOX
"HE RELUCTANTLY HANDS OVER HIS GUN, BUT HE HAS NO MONEY"
MSGBOX 'W' INCR
DROP
          ELSE
"...AND SHOOTS YOU THREE TIMES!"
MSGBOX -10 'HP'
STO+
          END
        END
        IF N 2 ==
WHO "C" == AND
        THEN
"UH-OH... YOU 
BUMPED INTO 
OFFICER HARDASS
!!"
MSGBOX PIG KILL
        END
        IF N 3 ==
        THEN
"YOU BEAT HIM UP
AND GET $"
RAND 12 * IP 1 +
1000 *
          IF WHO
"L" ==
          THEN 2 *
          END DUP
ROT SWAP +
" OFF HIM!" +
MSGBOX 'MON' STO+
        END
        IF N 4 ==
WHO "R" == WHO "C"
== OR AND
        THEN
"YOU GET 10 UNITS OF COKE OFF HIM!"
MSGBOX TCT TCT 1
GET
          IF POK
PUSED - 10 >
          THEN 10
          ELSE POK
PUSED -
          END DUP
'PUSED' STO+ + 1
SWAP PUT 'TCT' STO
        END
        IF N 5 ==
WHO "C" == AND
        THEN
"YOU GET HIS GUN!"
MSGBOX 'W' INCR
DROP
        END
        IF WHO "R"
== N 5 == AND
        THEN
"YOU GOT HIS COAT!"
MSGBOX 'POK' 25
STO+
        END
        IF N 2 ==
        THEN
"HE BEATS YOU 
UP AND YOU LOSE 7 HEALTH POINTS"
MSGBOX -7 'HP' STO+
        END
        IF HP 0 <
        THEN
"YOU HAVE DIED."
MSGBOX HOME 2 MENU
KILL
        END
        IF WHO "L"
== N 1 == AND
        THEN
"OOPS-- HE
GOT YOUR WALLET"
MSGBOX 0 'MON' STO
        END
        IF N 4 == N
5 == OR WHO "S" ==
AND
        THEN
          IF POK
PUSED - 6 \>=
          THEN
"YOU GET HIS 6
HEROINS!"
MSGBOX TCT TCT 2
GET 6 + 2 SWAP PUT
'TCT' STO 6 'PUSED'
STO+
          END
        END
        IF WHO "L"
== N 4 == AND
        THEN
          IF HP 20
<
          THEN 20
'HP' STO
"HE GETS YOU A
DOCTOR SINCE
YOU DON'T 
BEAT HIM UP."
MSGBOX
          ELSE
"HE AIN'T GOT
NOTHING ON HIM!"
MSGBOX
          END
        END
        IF WHO "L"
== N 5 == AND
        THEN
"HE'S TOO QUICK- HE CALLS THE
COPS ON HIS 
CELLULAR PHONE!"
MSGBOX PIG
        END
      \>>
    \>>
  LOAN
    \<< DBT IP 'DBT'
STO CLLCD
"LOAN SHARK" 1 DISP
"YOU OWE $" DBT + 7
DISP "DO WHAT?" {
"PAY BACK"
"TAKE LOAN" "LEAVE"
} 1 CHOOSE DROP DUP
      IF "LEAVE" ==
      THEN DROP
KILL
      END
      IF
"TAKE LOAN" ==
      THEN
"BORROW HOW MUCH?"
"" INPUT OBJ\-> DUP
DUP
        IF DBT +
7000 >
        THEN
"YOU THINK HE'S
CRAZY, MAN?"
MSGBOX CLEAR
        ELSE 'DBT'
STO+ 'MON' STO+
        END
      ELSE
"WALLET: $" MON + 1
DISP 1 WAIT
"PAY HOW MUCH?" ""
INPUT OBJ\-> DUP DUP
        IF DBT >
SWAP MON > OR
        THEN CLEAR
LOAN
        ELSE DUP
MON SWAP - 'MON'
STO DBT SWAP -
'DBT' STO
        END
      END LOAN
    \>>
  RANPR
    \<< 9000 4000 820
160 75 9 \-> LOWC
LOWH LOWA LOWW LOWS
LOWL
      \<< RAND 2.5 *
1 + LOWC * IP 'PC'
STO RAND 2.4 * 1 +
LOWH * IP 'PH' STO
RAND 3 * 1 + LOWA *
IP 'PA' STO RAND 3
* 1 + LOWW * IP
'PW' STO RAND 2.2 *
1 + LOWS * IP 'PS'
STO RAND 3.3 * 1 +
LOWL * IP 'PL' STO
      \>>
    \>>
  REV
    \<< CLLCD RAND 24
* IP 1 + \-> E
      \<<
        IF E 1 ==
        THEN
"PIGS MADE A BIG COKE BUST! 
PRICES ARE 
OUTRAGEOUS!"
MSGBOX RANPR RAND
60000 * 80000 + IP
'PC' STO
        END
        IF E 2 ==
        THEN
"ADDICTS BUYING HEROIN
AT OUTRAGEOUS PRICES!"
MSGBOX RANPR RAND
25000 * 18000 +
CEIL 'PH' STO
        END
        IF E 3 ==
        THEN
"ACID PRICES 
SKYROCKET!"
MSGBOX RANPR 4000
RAND 1 + * IP 'PA'
STO
        END
        IF E 4 ==
        THEN
"MARKET FLOODED 
WITH CHEAP 
HOMEMADE ACID!"
MSGBOX RANPR 400
'PA' STO
        END
        IF E 5 ==
        THEN
"RIVAL DEALERS ARE SELLING CHEAP LUDES!"
MSGBOX RANPR 2 'PL'
STO
        END
        IF E 6 ==
        THEN
"HEROIN PRICES 
BOTTOM-OUT!"
MSGBOX RANPR RAND
1150 * 850 + IP
'PH' STO
        END
        IF E 7 ==
        THEN
"COPS SELLING 
CHEAP COKE FROM 
LAST WEEK'S RAID!"
MSGBOX RANPR 6000
'PC' STO
        END
        IF E 8 == E
9 == OR E 14 == OR
        THEN SMOKE
        END
        IF E 10 ==
E 13 == OR
        THEN PIG
        END
        IF E 11 ==
E 12 == OR E 16 ==
OR E 18 == OR
        THEN YBUY
        END
        IF E 15 ==
        THEN RAND
100 * IP 20 * DUP
MON + 'MON' STO
"YOU FIND $" SWAP +
" ON A DEAD DUDE!"
+ MSGBOX
        END
        IF E 17 ==
        THEN
          IF HP 20
<
          THEN DOCT
          END
        END
        IF E 19 ==
DBT 0 > AND
        THEN
"THE LOAN SHARK'S "
"GOONS BUST YOU UP "
"FOR LATE PAYMENT "
"AND TAKE ALL YOUR "
"DRUGS!" 6 2
          FOR A A
DISP A FREEZE -1
          STEP REP
{ 0 0 0 0 0 0 }
'TCT' STO 0 'PUSED'
STO
        END
      \>>
    \>>
  SCOR
    \<< CLLCD -1 'D'
STO+
      IF MON ACCT +
1000000 \>=
      THEN
"YOU WIN!"
      ELSE
"YOU LOST!"
      END MSGBOX
MON ACCT + DUP
      IF 1000000 <
      THEN MON -
MON LOG 10000 *
1000000 +
      END 1000000 -
1000 / DBT 10 / -
IP HP + 20 D - DUP
      IF 0 <
      THEN DROP
      ELSE 100 * +
      END
      IF D 5 \<=
      THEN 5 D -
1000 * +
      END TCT EVAL
3 DROPN .5 * + SWAP
2 * + + PK 100 * +
IP DUP
      IF 0 <
      THEN 0 SWAP
DROP
      END F +
"AFTER " D +
" DAYS, " +
"YOUR SCORE WAS " +
SWAP + MSGBOX
"IF YOU LIKED
DRUGWARS/HAVE 
SUGGESTIONS,
EMAIL BRIAN AT:"
MSGBOX
"bhrian@hotmail.com"
2 DISP
"Brian Sennello" 1
DISP
"   You can order"
4 DISP
" custom games, too!"
5 DISP REP
      IF D 1 + 31 <
F 0 == AND
      THEN
"PLAY TILL DAY 31?"
{ "YES" "NO" } 1
CHOOSE DROP
        IF "NO" ==
        THEN 2 MENU
HOME CLEAR KILL
        END
      END
      IF D 30 >
      THEN
"KEEP PLAYING?" {
"YES" "NO" } 2
CHOOSE DROP
        IF "YES" ==
        THEN
"TYPE 'SCOR' 
AT ANY TIME 
TO SEE SCORE"
MSGBOX
        ELSE 2 MENU
HOME CLEAR KILL
        END
      END 1 'D'
STO+ "*" 'F' STO
    \>>
  PIG
    \<<
"OFFICER HARDASS
AND "
RAND 4 * CEIL DUP
'NP' STO +
" OF HIS 
PIGS ARE AFTER 
YOU!"
+ MSGBOX
      WHILE NP 0 >
HP 0 \>= AND
      REPEAT
        \<<
"DO WHAT?" { "RUN"
"SHOOT" }
          IF HP 10
<
          THEN
"DROP WALLET" +
          END 1
CHOOSE
          IF 0 ==
          THEN
"RUN"
          END DUP
          IF "RUN"
==
          THEN RAND
            IF .8 >
            THEN
"YOU LOST THEM
IN AN ALLEY!"
MSGBOX CLEAR KILL
            END
          END DUP
          IF
"SHOOT" ==
          THEN
            IF W 0
==
            THEN
"YOU HAVE NO WEAPONS! YOU HAVE TO RUN!"
MSGBOX
            ELSE
RAND W \v/ *
              IF
.75 >
              THEN
"YOU KILLED ONE!"
MSGBOX NP 1 - 'NP'
STO 'PK' INCR DROP
              ELSE
"YOU MISSED!"
MSGBOX
              END
            END
          END DUP
          IF
"DROP WALLET" ==
          THEN MON
0 'MON' STO RAND
DUP
            IF .82
>
            THEN
1001
            ELSE 0
            END
SWAP ROT * +
            IF 1000
>
            THEN
"YOU DISTRACTED THEM!"
MSGBOX DROP KILL
            ELSE
"THEY DIDN'T FALL FOR IT!"
MSGBOX
            END
          END DROP
"THEY'RE FIRING 
AT YOU!"
MSGBOX RAND NP \v/ .2
- *
          IF .75 >
          THEN
"THEY HIT YOU!"
MSGBOX HP 3 - 'HP'
STO "HEALTH:
" HP +
"/20" + MSGBOX
          ELSE
"THEY MISSED!"
MSGBOX
          END
        \>> EVAL
      END
      IF HP 0 <
      THEN
"THEY KILLED YOU.
   GAME OVER"
MSGBOX HOME 2 MENU
CLEAR KILL
      ELSE
"YOU KILLED THEM ALL!"
MSGBOX 2 'PK' STO+
      END
    \>>
  SMOKE
    \<<
"A GUY OFFERS YOU SOMETHING THAT SMELLS LIKE WEED."
MSGBOX
"DO YOU SMOKE IT?"
{ "YES" "NO" } 1
CHOOSE DROP
      IF "YES" ==
      THEN RAND 10
* CEIL \-> H
        \<<
          IF H 1 ==
          THEN
"YOU GO INSANE 
AND TRY TO FLY
BUT YOU FALL 
DOWN AND DIE."
MSGBOX 2 MENU HOME
KILL
          END
          IF H 2 ==
          THEN
"YOU GET WAY TOO HIGH AND RUN IN THE PATH OF AN 
ONCOMING SUBWAY"
MSGBOX 2 MENU HOME
KILL
          END
          IF H 3 ==
          THEN
"YOU FALL 
UNCONSCIOUS AND SOMEONE STEALS YOUR WALLET."
MSGBOX 0 'MON' STO
          END
          IF H 4 ==
          THEN
"A COP SEES YOU
SMOKING IT! 
HE'S CHASING YOU!"
MSGBOX PIG
          END
          IF H 6 ==
          THEN
"YOU GO INSANE 
AND ROB A GUY'S HOUSE.  YOU GET
$3000"
MSGBOX MON 3000 +
'MON' STO
          END
          IF H 7 ==
          THEN
"YOU BRAINSTORM
A WAY TO MAKE
LETTUCE SMELL
LIKE WEED."
MSGBOX TCT POK
PUSED - POK 'PUSED'
STO TCT 4 GET + 4
SWAP PUT 'TCT' STO
          END
          IF H 8 ==
          THEN
"A BUM TAKES PITY ON YOUR PATHETIC STATE AND GIVES YOU 4 UNITS OF COKE."
MSGBOX
            IF
PUSED 4 + POK <
            THEN
TCT TCT 1 GET 4 + 1
SWAP PUT 'TCT' STO
PUSED 4 + 'PUSED'
STO
            END
          END
          IF H 9 ==
          THEN
"YOU FIND A $100 BILL INSIDE"
MSGBOX MON 100 +
'MON' STO
          END
          IF H 10
==
          THEN
"YOU GO ON THE
WILDEST TRIP OF
YOUR LIFE AND
STEAL $"
RAND 4000 * IP DUP
ROT SWAP +
"
WORTH OF STUFF" +
MSGBOX 'MON' STO+
          END
        \>>
      END
    \>>
  YBUY
    \<< RAND
      IF .33 <
      THEN "GUN"
      ELSE
        IF HP 20 <
        THEN DOCT
KILL
        ELSE
"NEW TRENCHCOAT WITH MORE 
POCKETS"
        END
      END \-> YBO
      \<< RAND 10 *
CEIL 100 * DUP DUP
        IF MON >
        THEN DROP2
KILL
        END
"WILL YOU BUY A
"
YBO + SWAP " FOR $"
SWAP + + "?" +
MSGBOX "" { "YES"
"NO" } 1 CHOOSE
DROP
        IF "NO" ==
        THEN DROP
KILL
        END
        IF YBO
"GUN" ==
        THEN 'W'
INCR DROP MON SWAP
- 'MON' STO
        ELSE MON
SWAP - 'MON' STO
POK 25 + 'POK' STO
        END
      \>>
    \>>
  DOCT
    \<< RAND 20 HP -
* 100 * CEIL 10 * \->
C
      \<<
        IF C MON >
        THEN KILL
        END
"WILL YOU HAVE A DOCTOR STITCH YOU UP FOR $"
C + "?" + MSGBOX ""
{ "YES" "NO" } 1
CHOOSE DROP
        IF "YES" ==
        THEN 20
'HP' STO MON C -
'MON' STO
        END KILL
      \>>
    \>>
  NP 0
  PK 0
  PC 18661
  PH 11250
  PA 1717
  PW 617
  PS 210
  PL 35
  PD 0
  WD 0
  D 1
  F 0
  HP 20
  W 0
  TCT { 0 0 0 0 0 0
}
  LOC "NOB HILL"
  MON 2000
  PUSED 0
  POK 50
  CST { PRICE COAT
BUY SELL JET OTHER
MSGBOX ORDER BYTES
CHOOSE }
  ACCT 0
  DBT 2000
  GAMS
    DIR
      FUN { 0 0 0 1
20 5 { 0 0 0 0 0 0
} "NOB HILL" 24350
4912 2039 210 95 2
0 200 999999 }
      DR { 20732038
0 4 24 14 1 { 50 0
0 0 0 0 }
"NOB HILL" 22224
8761 2376 200 139
22 50 350 1582768 }
    END
END
