%%HP: T(3)A(D)F(.);
DIR
  GRAV
    \<< RCLF \-> f
      \<< 2 CF INIT 2
SF
        WHILE 2 FS?
        REPEAT
SENDMIS
        END f STOF
      \>> { GRAV }
ORDER 2 MENU KILL
    \>>
  PPAR {
(-6.5,-3.1)
(6.5,3.2) X 0 (0,0)
FUNCTION Y }
  FORCE
95.4679287494
  T .2
  HitSom 3
  XM 43.2321441059
  YM 24.78987535
  VY 4.54006797474
  VX 6.02492180378
  NUM.P 3
  POSITION { { 43
28 3 } { 99 25 4 }
{ 59 35 1 } { 14 35
6 } { 78 29 2 } }
  DTIME .2
  ANGLE 135
  Gk 360
  VINIT 12
  MIN.FORC .001
  TIME.MAG 5
  MNUM 6
  MAX.MIS 10
  S.SIZE 3
  T.SIZE 4
  MAX.PL 5
  INIT
    \<< GETSEED ERASE
{ # 0d # 0d } PVIEW
5 'MAX.PL' STO 4
'T.SIZE' STO 3
'S.SIZE' STO 10
'MAX.MIS' STO 10
'MNUM' STO 5
'TIME.MAG' STO .001
'MIN.FORC' STO 12
'VINIT' STO 360
'Gk' STO 0 'ANGLE'
STO .2 'DTIME' STO
{ } 'POSITION' STO
MAX.PL 1 - RAND *
IP 2 + 'NUM.P' STO
GENSTAT GENTARG
GENPLAN ANGLE
SETMIS
    \>>
  GETSEED
    \<<
"Enter random seed or
"
"Nothing if don't care
"
+ "Push ENTER" + ""
INPUT DUP SIZE
      IF 0 \=/
      THEN OBJ\-> RDZ
      ELSE DROP
      END
    \>>
  GENTARG
    \<< POSITION 24
RAND * IP 87 + 24
RAND * IP 20 +
T.SIZE 3 \->LIST 1
\->LIST + 'POSITION'
STO DTARG
    \>>
  DTARG
    \<< PICT POSITION
2 GET OBJ\-> DROP2
SWAP 4 - R\->B SWAP 4
- R\->B 2 \->LIST TARG
REPL
    \>>
  GENSTAT
    \<< POSITION 24
RAND * IP 20 + 24
RAND * IP 20 +
S.SIZE 3 \->LIST 1
\->LIST + 'POSITION'
STO DSTAT
    \>>
  DSTAT
    \<< PICT POSITION
1 GET OBJ\-> DROP2
SWAP 3 - R\->B SWAP 3
- R\->B 2 \->LIST STAT
REPL
    \>>
  GENPLAN
    \<< 3 0 0 \-> i x y
      \<<
        DO POSITION
110 RAND * IP 10 +
DUP R\->B 'x' STO 40
RAND * IP 10 + DUP
R\->B 'y' STO x y 2
\->LIST DUP 'x' STO
PIXON
          IF 5 FS?
          THEN 6
RAND * IP 1 +
          ELSE 5
RAND * IP 2 +
          END 3
\->LIST 1 \->LIST +
'POSITION' STO 1 CF
1 i 1 -
          FOR j i j
CALDIFF
            IF 12 <
            THEN 1
SF
            END
          NEXT x
PIXOFF
          IF 1 FC?
          THEN i
DPLAN 1 'i' STO+
          ELSE
POSITION DUP SIZE 1
- 1 SWAP SUB
'POSITION' STO
          END
        UNTIL i
NUM.P 2 + >
        END
      \>>
    \>>
  DPLAN
    \<< POSITION SWAP
GET OBJ\-> DROP R\->B 3
ROLLD R\->B SWAP R\->B
SWAP 2 \->LIST SWAP 0
6.28 RAD ARC
    \>>
  CALDIFF
    \<< \-> i j
      \<< POSITION j
GET OBJ\-> DROP
POSITION i GET OBJ\->
DROP 4 ROLL + 5
ROLLD SWAP 3 ROLLD
- DUP * 3 ROLLD -
DUP * + \v/ SWAP -
      \>>
    \>>
  REDRAW
    \<< ERASE { # 0d
# 0d } PVIEW DSTAT
DTARG 3 NUM.P 2 +
      FOR j j DPLAN
      NEXT
    \>>
  SENDMIS
    \<< 3 CF 0
'HitSom' STO
      IF MNUM 0 ==
      THEN 2 CF
      ELSE TEXT
CLLCD { { "VIEW"
        \<< { # 0d
# 0d } PVIEW WAITK
DHELP
        \>> } {
"REDR"
        \<< REDRAW
DHELP
        \>> } {
"SHOT"
        \<< TEXT
CLLCD ""
          IF MNUM
MAX.MIS \=/
          THEN
"Last Angle was " +
2 FIX ANGLE \->STR +
"
" +
          END
"Input angle, push CONT"
+ "    90" 3 DISP
"180 ** 0" 4 DISP
"   -90" 5 DISP 3
FREEZE PROMPT DUP
'ANGLE' STO SETMIS
DHELP
        \>> } {
"CONT" CONT } {
"GO" CONT } {
"QUIT"
        \<< 2 CF 6
'HitSom' STO CONT
        \>> } } TMENU
DHELP HALT MNUM 1 -
'MNUM' STO { # 0d
# 0d } PVIEW
        WHILE
HitSom NOT
        REPEAT
UPDATE DRAWXY
EVALPOS
        END
      END
    \>>
  SETMIS
    \<< NEG DUP DEG
COS VINIT * 'VX'
STO SIN VINIT *
'VY' STO POSITION 1
GET OBJ\-> DROP2 'YM'
STO 'XM' STO
    \>>
  DHELP
    \<< TEXT CLLCD
"VIEW - See Planets"
1 DISP
"REDR - Redraw Screen"
2 DISP
"SHOT - Enter Angle"
3 DISP
"GO   - Launch Missile"
4 DISP
"QUIT - Restore and End"
5 DISP MNUM STD
\->STR " Missle" +
      IF MNUM 1 \=/
      THEN "s" +
      END " Left" +
7 DISP 3 FREEZE
    \>>
  UPDATE
    \<< 0 0 \-> fx fy
      \<<
        IF XM DUP 0
< SWAP 130 > OR YM
DUP 0 < SWAP 63 >
OR OR
        THEN
TIME.MAG DTIME *
        ELSE DTIME
        END 'T' STO
3 NUM.P 2 +
        FOR i i
CALDIST \-> x y m d
          \<<
            IF d 8
\<= m 12 == AND
            THEN T
d * 10 / 'T' STO
            END y
YM - m * Gk * d DUP
DUP * * DUP 3 ROLLD
/ 'fy' STO+ x XM -
m * Gk * SWAP /
'fx' STO+
          \>>
        NEXT fx T *
'VX' STO+ fy T *
'VY' STO+ VX T *
'XM' STO+ VY T *
'YM' STO+ fx DUP *
fy DUP * + 'FORCE'
STO
      \>>
    \>>
  CALDIST
    \<< POSITION SWAP
GET DUP OBJ\-> DROP2
YM - DUP * SWAP XM
- DUP * + \v/ SWAP
OBJ\-> DROP DUP
      IF 1 ==
      THEN DROP 12
      END 4 ROLL
    \>>
  DRAWXY
    \<< XM R\->B YM R\->B
2 \->LIST PIXON
    \>>
  EVALPOS
    \<<
      IF KEY
      THEN 5
'HitSom' STO
      ELSE
        IF DTIME
TIME.MAG * T ==
        THEN
          IF FORCE
MIN.FORC <
          THEN 4
'HitSom' STO
          END
        ELSE 3
NUM.P 2 +
          FOR i i
CALDIST SWAP DUP
            IF 12
==
            THEN
DROP 1.2
            END
SWAP \-> x y m d
            \<<
              IF d
m \<=
              THEN
1 'HitSom' STO
IF m 1.2 ==
THEN 9 'HitSom' STO
END
              END
            \>>
          NEXT 1
CALDIST
          IF 3 FC?
          THEN
            IF
S.SIZE 1 + >
            THEN 3
SF
            END
          ELSE
            IF
S.SIZE 1 + \<=
            THEN 3
'HitSom' STO
            END
          END 2
CALDIST
          IF T.SIZE
1 + \<=
          THEN 2
'HitSom' STO
          END
        END
      END CLEAR
MESS
    \>>
  MESS
    \<<
      IF HitSom
      THEN TEXT
CLLCD
        CASE HitSom
9 ==
          THEN
"Fell into Black Hole"
          END
HitSom 1 ==
          THEN
"Hit Planet"
          END
HitSom 2 ==
          THEN
"You Hit the Target
Using "
MAX.MIS MNUM - STD
\->STR + " Missile" +
            IF
MAX.MIS MNUM - 1 \=/
            THEN
"s" +
            END 2
CF
          END
HitSom 3 ==
          THEN
"You Blew Yourself Up"
2 CF
          END
HitSom 4 ==
          THEN
"Missle Escaped System"
          END
HitSom 5 ==
          THEN
"Missle Aborted"
          END
        END 1 DISP
        IF MNUM 0
==
        THEN
"Game Over No Missiles"
3 DISP
        END
"  Push any key EXCEPT"
4 DISP
"  ATTN/ON to continue"
5 DISP WAITK
      END
    \>>
  WAITK
    \<< 0 WAIT DROP
    \>>
  STAT
GROB 7 7 C141F755F741C1
  TARG
GROB 9 9 8300EF006C00BB10BA10BB106C00EF008300
  SAV1
    \<< {
1612.56253429 .2 1
11.6543554827
28.0091123754
26.5268840627
1.59583482572 2 { {
40 28 3 } { 96 27 4
} { 12 30 6 } { 52
13 3 } } .2
159.975913 360 12
.001 5 5 10 3 4 5 }
{ FORCE T HitSom XM
YM VY VX NUM.P
POSITION DTIME
ANGLE Gk VINIT
MIN.FORC TIME.MAG
MNUM MAX.MIS S.SIZE
T.SIZE MAX.PL } \->
SAV1A SAV1B
      \<< 1 20
        FOR A SAV1A
A GET SAV1B A GET
STO
        NEXT
      \>>
    \>>
END
