%%HP: T(3)A(D)F(.);
DIR
  PPAR { (1,0)
(10,3504.15566193)
X 0 (0,0) FUNCTION
Y }
  INIT { 1 0 .1 90
}
  EQNS { '1000*X*
EXP(-.5*X)' }
  VARI { X Y }
  EULER
    \<<
      IF
"# OF RATE EQUATIONS:"
{ 3 2 1 } 1 CHOOSE
      THEN \-> J
        \<<
          IF VARI
SIZE J 1 + \=/ 'VARI'
VTYPE -1 == OR
          THEN { }
'VARI' STO
          END
"VARIABLES" {
"INDEPENDENT:" "" 6
} 1 J
          START {
"DEPENDENT:" "" 6 }
          NEXT J 1
+ \->LIST { 1 0 }
VARI DUP
          IF INFORM
          THEN \-> V
            \<< V
'VARI' STO
              IF
EQNS SIZE J \=/
'EQNS' VTYPE -1 ==
OR
              THEN
{ } 'EQNS' STO
              END V
TAIL 1
              \<<
\->STR TAIL " =" + {
"ENTER RATE WITHIN TICK MARKS."
0 6 9 } +
              \>>
DOLIST
"RATE EQUATIONS"
SWAP { 1 0 } EQNS
DUP
              IF
INFORM
              THEN
DUP 'EQNS' STO V {
{ \<-X } { \<-V1 } {
\<-V2 } { \<-V3 } } 1 J
1 + SUB ADD SWAP 1
J 1 +
FOR I OVER I GET 1
J
  START DUP
  NEXT DROP J \->LIST
2
  \<< \|vMATCH DROP
  \>> DOLIST
NEXT \-> NEWEQ
\<< DROP
  IF INIT SIZE J 3
+ \=/ 'INIT' VTYPE -1
== OR
  THEN { } 'INIT'
STO
  END V 1
  \<< \->STR DUP SIZE 1
- 2 SWAP SUB ":" +
{
"ENTER INITIAL VALUE."
0 } +
  \>> DOLIST { {
"STEP SIZE:"
"ENTER STEP SIZE."
0 } { "#STEPS:"
"ENTER NUMBER OF STEPS."
0 } } + \-> B
  \<<
    WHILE
"INITIAL STATE" B {
2 0 } INIT DUP
INFORM
    REPEAT DUP
'INIT' STO NEWEQ +
OBJ\-> DROP
      IF
"WHICH OPTION?" { {
VALUE 1 } { PLOT 0
} } 1 CHOOSE
      THEN
        IF
        THEN
          CASE J 3
==
            THEN \->
H N R1 R2 R3
              \<< 1 N
START \-> \<-X \<-V1 \<-V2
\<-V3
  \<< \<-X H + R1 EVAL
H * \<-V1 + R2 EVAL H
* \<-V2 + R3 EVAL H *
\<-V3 +
  \>>
NEXT
              \>>
            END J 2
==
            THEN \->
H N R1 R2
              \<< 1 N
START \-> \<-X \<-V1 \<-V2
  \<< \<-X H + R1 EVAL
H * \<-V1 + R2 EVAL H
* \<-V2 +
  \>>
NEXT
              \>>
            END J 1
==
            THEN \->
H N R1
              \<< 1 N
START \-> \<-X \<-V1
  \<< \<-X H + R1 EVAL
H * \<-V1 +
  \>>
NEXT
              \>>
            END
          END
        ELSE 0 0 J
2 * 5 + ROLLD J 2 *
5 + ROLLD
          CASE J 3
==
            THEN \->
H N R1 R2 R3
              \<< 4
PICK DUP H N * +
DUP2 MIN 3 ROLLD
MAX XRNG 1 N
START \-> \<-X \<-V1 \<-V2
\<-V3
  \<< \<-V1 \<-V2 \<-V3 MAX
MAX MAX SWAP \<-V1
\<-V2 \<-V3 MIN MIN MIN
SWAP \<-X H + R1 EVAL
H * \<-V1 + R2 EVAL H
* \<-V2 + R3 EVAL H *
\<-V3 +
  \>>
NEXT 3 DUPN 9 ROLL
MIN MIN MIN 4 DUPN
DROP 9 ROLL MAX MAX
MAX YRNG
              \>>
ERASE { # 0d # 0d }
PVIEW INIT NEWEQ +
OBJ\-> DROP \-> H N R1
R2 R3
              \<< 1 N
START \-> \<-X \<-V1 \<-V2
\<-V3
  \<< \<-X \<-V1 R\->C
PIXON \<-X \<-V2 R\->C
PIXON \<-X \<-V3 R\->C
PIXON \<-X H + R1
EVAL H * \<-V1 + R2
EVAL H * \<-V2 + R3
EVAL H * \<-V3 +
  \>>
NEXT 4 DUPN 4 PICK
SWAP R\->C PIXON 3
PICK SWAP R\->C PIXON
R\->C PIXON
              \>>
            END J 2
==
            THEN \->
H N R1 R2
              \<< 3
PICK DUP H N * +
DUP2 MIN 3 ROLLD
MAX XRNG 1 N
START \-> \<-X \<-V1 \<-V2
  \<< \<-V1 \<-V2 MAX MAX
SWAP \<-V1 \<-V2 MIN
MIN SWAP \<-X H + R1
EVAL H * \<-V1 + R2
EVAL H * \<-V2 +
  \>>
NEXT DUP2 7 ROLL
MIN MIN 3 DUPN DROP
7 ROLL MAX MAX YRNG
              \>>
ERASE { # 0d # 0d }
PVIEW INIT NEWEQ +
OBJ\-> DROP \-> H N R1
R2
              \<< 1 N
START \-> \<-X \<-V1 \<-V2
  \<< \<-X \<-V1 R\->C
PIXON \<-X \<-V2 R\->C
PIXON \<-X H + R1
EVAL H * \<-V1 + R2
EVAL H * \<-V2 +
  \>>
NEXT 3 DUPN 3 PICK
SWAP R\->C PIXON R\->C
PIXON
              \>>
            END J 1
==
            THEN \->
H N R1
              \<<
OVER DUP H N * +
DUP2 MIN 3 ROLLD
MAX XRNG 1 N
START \-> \<-X \<-V1
  \<< \<-V1 MAX SWAP
\<-V1 MIN SWAP \<-X H +
R1 EVAL H * \<-V1 +
  \>>
NEXT DUP 5 ROLL MIN
DUP2 DROP 5 ROLL
MAX YRNG
              \>>
ERASE { # 0d # 0d }
PVIEW INIT NEWEQ +
OBJ\-> DROP \-> H N R1
              \<< 1 N
START \-> \<-X \<-V1
  \<< \<-X \<-V1 R\->C
PIXON \<-X H + R1
EVAL H * \<-V1 +
  \>>
NEXT DUP2 R\->C PIXON
              \>>
            END
          END
PICTURE
        END CLLCD J
1 + \->LIST V
        \<< \->TAG
        \>> DOLIST ""
SWAP 0 CHOOSE DROP
      END CLEAR
    END
  \>>
\>>
              END
            \>>
          END
        \>>
      END
    \>>
END
