%%HP: T(3)A(D)F(.);
DIR
  REBEL
    \<< CLLCD
"---- REBEL GUNNER ----"
1 DISP 1 FREEZE
"Not just another Star
Wars shooting game"
3 DISP 3 FREEZE
"Created by" 6 DISP
6 FREEZE
"Brian Sennello" 7
DISP 7 FREEZE 1
MENU REP CLLCD
"LEVEL:" { 1 2 3 }
2 CHOOSE DROP 'L'
STO "INSTRUCTIONS?"
{ "YES" "NO" } 2
CHOOSE DROP
      IF "NO" ==
      THEN CLEAR
KILL
      END
"  IN THE GAME "
"'REBEL GUNNER'"
"YOU ARE A GUNNER IN A"
"GUN TURRET ON A "
"CORRELLIAN CORVETTE."
5 1
      FOR A A DISP
A FREEZE -1
      STEP REP
"WHILE ON A PEACEFUL"
"MISSION, YOUR CORVETTE"
"IS ATTACKED BY A GROUP"
"OF TIE FIGHTERS AND"
"BOMBERS. AS GUNNER,"
"IT IS YOUR DUTY TO"
"DEFEND YOUR SHIP."
7 1
      FOR A A DISP
A FREEZE -1
      STEP REP
"YOUR CONTROLS ARE THE"
"TOP ROW OF WHITE KEYS"
"AND THE ARROW KEYS."
"ON THE FOLLOWING"
"LIST, THE #s IN ()"
"SHOW THE ENERGY USED"
"BY EACH SYSTEM." 7
1
      FOR A A DISP
A FREEZE -1
      STEP REP
"A: FIRE LASER (2)"
"B: BOOST SHIELD(5)"
"C: FIRE TORPEDO (15)"
"D: START / PAUSE "
"E: ASSESS DAMAGE (0)"
"F: CHECK SENSORS (0)"
"\<-\|^\|v\->: MOVE TARGET(0)"
7 1
      FOR A A DISP
A FREEZE -1
      STEP REP
"THIS IS THE
NEBULON-B SHIP
'SUTTER'.  WE 
WILL ARRIVE TO
HELP SHORTLY."
MSGBOX
"  THE 'SUTTER' WILL"
"COME TO OUR AID IN A"
"FEW MINUTES. HOLD OUT"
"UNTIL THEN, IF YOU CAN"
CLLCD 5 2
      FOR A A DISP
A FREEZE -1
      STEP REP
CLLCD
"ON THE NEXT
SCREEN, PRESS 
'START' TO 
BEGIN."
MSGBOX
    \>>
  START.
    \<< PICT PURGE 0
DUP DUP DUP2 DUP2
'GH' STO 'GV' STO
'BH' STO 'D1' STO
'D2' STO 'D3' STO
'D4' STO 2 'BV' STO
-1 'TH' STO 0 'TV'
STO 10 'TPV' STO 10
'BTPV' STO 100
'BHU' STO 5 4 L - *
'E' STO 2 'BTP' STO
100 'S' STO D.PLR
MOV 'PLAYR' PURGE
PICT PURGE
    \>>
  MOV
    \<< 1 40 L *
      FOR A A 'T'
STO CMD 1 'E' STO+
PICT "ENERGY:" E +
"              SHD:"
+ S + 1 \->GROB
(-6.5,3.1) SWAP GOR
        IF TV 10 \=/
        THEN M.TF
        END
        IF BV 10 \=/
        THEN M.TB
        END
        IF TPV 3.1
\<=
        THEN M.TP
        END
        IF BTPV 10
\=/
        THEN M.BTP
        END ENFIRE
PICT GH .2 - GV .2
+ R\->C I.TAR GXOR
PICT { # 0d # 0d }
{ # 130d # 63d }
SUB \->LCD PICT
(-6.5,3.2) PLAYR
REPL
        IF S 1 <
        THEN WDAM 1
'S' STO
        END
        IF TV BV ==
        THEN 'T'
PURGE "YOU WON!"
MSGBOX "IN " A +
" SECONDS" +
"
SHIELDS AT " + S
+ "%" +
"
ENERGY AT " + E +
"
DAMAGE: -" D1 D2
D3 D4 + + + 20 * +
"
SCORE " + 100 A -
S + E + D1 D2 D3 D4
+ + + -20 * + + +
MSGBOX 'PLAYR'
PURGE KILL
        END CMD
        IF BTPH 0
== BTPV 0 == AND
        THEN TPHIT
        END
      NEXT
"THE NEBULON-B
FRIGATE 
'SUTTER' HAS
ARRIVED."
MSGBOX
"THE SUTTER
DESTROYS THE
REMAINING TIES
AND RESCUES
YOUR CREW."
MSGBOX 'T' PURGE
    \>>
  CMD
    \<<
      IF KEY 0 \=/
      THEN DUP
        IF 11 ==
        THEN FIRE
        END DUP
        IF 12 ==
        THEN \->SHD
        END DUP
        IF 13 ==
        THEN TORP
        END DUP
        IF 14 ==
        THEN
"GAME PAUSED" {
"RESUME" "QUIT" } 1
CHOOSE DROP HEAD
          IF "Q" ==
          THEN DROP
'PLAYR' PURGE HOME
2 MENU KILL
          END
        END DUP
        IF 15 ==
        THEN DAMG
        END DUP
        IF 16 ==
        THEN VIEW
        END DUP \-> I
        \<<
          IF I 25
== I 34 == OR I 35
== OR I 36 == OR
          THEN TARG
          END
        \>> DROP
      END
    \>>
  TARG
    \<< \-> D
      \<<
        IF D3 1 \=/
        THEN
          IF D 25
==
          THEN .5
'GV' STO+
          END
          IF D 35
==
          THEN -.5
'GV' STO+
          END
          IF D 34
==
          THEN -.5
'GH' STO+
          END
          IF D 36
==
          THEN .5
'GH' STO+
          END
        END D
      \>>
    \>>
  FIRE
    \<<
      IF D1 1 \=/
      THEN
        IF E 2 \>=
        THEN -3 'E'
STO+ GH GV R\->C
(0,-3) LINE
          IF TV GV
- .8 < TV GV - 0 >
AND TH GH - -.6 >
TH GH - 0 < AND AND
          THEN PICT
TH TV R\->C I.EXPL
REPL 10 'TV' STO
          END
          IF GH
BTPH - ABS .2 < GV
BTPV - ABS .2 < AND
          THEN PICT
GH .3 - GV .4 + R\->C
I.EXPL REPL 10
'BTPV' STO
            IF Z
TYPE 6 \=/
            THEN
              IF Z
1 ==
              THEN
50 'S' STO+
              END
            END
          END
          IF BV GV
- .7 < BV GV - 0 >
AND BH GH - -1 > BH
GH - 0 < AND AND
          THEN -25
'BHU' STO+
            IF BHU
1 <
            THEN
PICT BH BV R\->C
I.EXPL REPL 10 'BV'
STO
            END
          END
        END
      END
    \>>
  TORP
    \<<
      IF D2 1 \=/
      THEN
        IF E 15 \>=
        THEN -16
'E' STO+ -3 -1
          FOR A
            \<<
              IF TV
10 \=/
              THEN
M.TF
              END
              IF BV
10 \=/
              THEN
M.TB
              END
              IF
BTPV 10 \=/
              THEN
M.BTP
              END
PICT 0 A 2 / R\->C
C.TORP A NEG \->GROB
GOR PICT { # 0d
# 0d } { # 130d
# 63d } SUB \->LCD
PLAYR PICT STO
            \>> EVAL
          NEXT 0
DUP 'TPH' STO 'TPV'
STO
        END
      END
    \>>
  \->SHD
    \<<
      IF E 6 \>= S
100 \<= AND
      THEN -6 'E'
STO+ 10 'S' STO+
      END
      IF S 100 >
      THEN 100 'S'
STO
      END
    \>>
  DAMG
    \<< CLLCD
"DAMAGE (1 = DAMAGED)"
1 DISP 1 FREEZE
"LASER: " D1 + 3
DISP 3 FREEZE
"TORPEDOS: " D2 + 4
DISP 4 FREEZE
"TARGETING SYS: "
D3 + 5 DISP 5
FREEZE "SENSORS: "
D4 + 6 DISP 6
      IF S 0 <
      THEN 0 'S'
STO
      END FREEZE
"SHIELDS: " S + "%"
+ 7 DISP 7 FREEZE
REP
    \>>
  VIEW
    \<<
      IF D4 1 \=/
      THEN CLLCD
"TIE BOMBER--" 1
DISP 1 FREEZE
"HULL: " BHU "%" +
+ 2 DISP 2 FREEZE
"WARHEADS: " BTP +
3 DISP 3 FREEZE
"SUTTER(DIST):" 40
L * T - + 5 DISP 5
FREEZE
"PRESS KEY TO EXIT"
7 DISP 7 FREEZE REP
      END
    \>>
  ENFIRE
    \<< RAND 7 L - *
IP \-> R
      \<<
        IF R 0 ==
TV 10 \=/ AND
        THEN RAND
          IF .5 <
          THEN TH
.4 + TV .5 - R\->C
(0,0) LINE PICT
(-.3,.4) I.EXPL
REPL -15 'S' STO+
            IF TPV
TPH + 0 ==
            THEN 10
'TPV' STO
            END
          ELSE TH
.4 + TV .7 - R\->C
(0,5) LINE
          END
        END
        IF R 1 ==
BV 10 \=/ AND
        THEN RAND
          IF .45 <
          THEN BH
.5 + BV .4 - R\->C
(0,0) LINE PICT
(-.3,.4) I.EXPL
REPL -15 'S' STO+
            IF TPH
ABS .5 \<= TPV ABS .5
\<= AND
            THEN 10
'TPV' STO
            END
          ELSE BH
.5 + BV .4 - R\->C
(0,4) LINE
          END
        END
        IF R 4 ==
BV 10 \=/ AND BTP 0 >
AND RAND .2 < AND
        THEN BSTP
        END
      \>>
    \>>
  BSTP
    \<< -1 'BTP' STO+
BH .5 + 'BTPH' STO
BV .4 - 'BTPV' STO
    \>>
  TPHIT
    \<< 1 'Z' STO
PICT (-.5,.5)
I.BTP1 GOR 1 'E'
STO+ PICT "ENERGY:"
E +
"              SHD:"
+ S + 1 \->GROB
(-6.5,3.1) SWAP GOR
      IF TV 10 \=/
      THEN M.TF
      END
      IF BV 10 \=/
      THEN M.TB
      END
      IF TPV 3.1 \<=
      THEN M.TP
      END
      IF BTPV 10 \=/
      THEN M.BTP
      END PICT GH
.2 - GV .2 + R\->C
I.TAR GOR PICT {
# 0d # 0d } {
# 130d # 63d } SUB
\->LCD PICT
(-6.5,3.2) PLAYR
REPL CMD PICT
(-.5,.5) I.BTP GOR
1 'E' STO+ PICT
"ENERGY:" E +
"              SHD:"
+ S + 1 \->GROB
(-6.5,3.1) SWAP GOR
      IF TV 10 \=/
      THEN M.TF
      END
      IF BV 10 \=/
      THEN M.TB
      END
      IF TPV 3.1 \<=
      THEN M.TP
      END
      IF BTPV 10 \=/
      THEN M.BTP
      END PICT GH
.2 - GV .2 + R\->C
I.TAR GOR PICT {
# 0d # 0d } {
# 130d # 63d } SUB
\->LCD PICT
(-6.5,3.2) PLAYR
REPL CMD 10 'BTPV'
STO PICT (-.8,.5)
I.EXPL REPL PICT
(0,.5) I.EXPL REPL
-30 10 L * - 'S'
STO+ 'Z' PURGE
    \>>
  WDAM
    \<< RAND 5 * IP \->
R
      \<<
        IF R 0 ==
        THEN CLLCD
"GUN TURRET #1 
HAS BEEN 
DESTROYED. ALL
GUNNERS DIED."
MSGBOX { PLAYR T }
PURGE 2 MENU HOME
KILL
        END
        IF R 1 ==
        THEN 1 'D1'
STO
        END
        IF R 2 ==
        THEN 1 'D2'
STO
        END
        IF R 3 ==
        THEN 1 'D3'
STO
        END
        IF R 4 ==
        THEN 1 'D4'
STO
        END
      \>>
    \>>
  M.TF
    \<< RAND .5 -
RAND .5 - \-> X Y
      \<< 'TH' X STO+
TH 'TV' Y STO+ TV
        IF TV 3.1 >
        THEN -.8
'TV' STO+
        END
        IF TV -3 <
        THEN .8
'TV' STO+
        END R\->C
PICT SWAP I.TIE
        IFERR GOR
        THEN CLEAR
        END
      \>>
    \>>
  M.TB
    \<< RAND .5 -
RAND .5 - \-> X Y
      \<< 'BH' X STO+
BH 'BV' Y STO+
        IF BV 3.1 >
        THEN -.8
'BV' STO+
        END
        IF BV -3.1
<
        THEN .8
'BV' STO+
        END BV R\->C
PICT SWAP I.TB
        IFERR GOR
        THEN DROP
DROP2
        END
      \>>
    \>>
  M.TP
    \<< PICT TPH TPV
R\->C I.TORP GOR
      IF BV TPV -
ABS .5 <
      THEN BV .4 -
'TPV' STO
      END BV .4 -
TPV - SIGN 2 /
'TPV' STO+
      IF BH TPH -
ABS .5 <
      THEN BH .5 +
'TPH' STO
      END BH .5 +
TPH - SIGN 2 /
'TPH' STO+
      IF TPH BH .5
+ - ABS .3 \<= TPV BV
.4 - - ABS .3 \<= AND
      THEN PICT BH
BV R\->C I.EXPL REPL
10 DUP 'BV' STO
'TPV' STO 0 'BHU'
STO 0 'BTP' STO
      END
    \>>
  M.BTP
    \<< PICT BTPH
BTPV R\->C I.TORP GOR
      IF 0 BTPV -
ABS .5 <
      THEN 0 'BTPV'
STO
      END 0 BTPV -
SIGN 4 / 'BTPV'
STO+
      IF 0 BTPH -
ABS .5 <
      THEN 0 'BTPH'
STO
      END 0 BTPH -
SIGN 4 / 'BTPH'
STO+
    \>>
  D.PLR
    \<< (-2,1.2)
(2,-1.2) BOX
(-2,1.2) (-6.5,3.2)
LINE (2,1.2)
(6.5,3.2) LINE
(-2,-1.2)
(-6.5,-3.1) LINE
(2,-1.2) (6.5,-3.1)
LINE PICT { # 0d
# 0d } { # 130d
# 63d } SUB 'PLAYR'
STO
    \>>
  I.TIE
GROB 8 11 1818181899FF9918181818
  I.TB
GROB 11 10 401020201040DD5077707770DD50104020204010
  I.TORP
GROB 2 2 3030
  C.TORP "
"
  I.EXPL
GROB 11 11 2200804049201410840013408A00A810002025002800
  I.TAR
GROB 5 5 F1115111F1
  I.BTP1
GROB 11 11 0000000000008F008F008F008F008F00000000000000
  I.BTP
GROB 11 11 FF70FF70FF70FF70FF70FF70FF70FF70FF70FF70FF70
  D1 0
  D2 0
  D3 0
  D4 0
  TH -.520228485825
  TV 10
  BH -.270053155413
  BV 10
  GH 0
  GV 0
  TPH .229946844587
  TPV 10
  BTPH 0
  BTPV 10
  BTP 0
  BHU 0
  E 0
  S 85
  REP
    \<<
      WHILE KEY 0
==
      REPEAT
      END DROP
    \>>
  L 1
  PPAR {
(-6.5,-3.1)
(6.5,3.2) X 0 (0,0)
FUNCTION Y }
  CST { FIRE \->SHD
TORP START. DAMG
VIEW RND ORDER PICT
BYTES \->LCD OBJ\-> }
END
