=========================================================================
    Hello , friends, nice idea you have to build up such a bbs !!!
Here is my contribution: a program to draw bode plots (and grid for decades)
which use the auto scale capability of statistical plots on hp-28.
    Here it is:
 
<< -> TR FRMI FRMA
  << TR 'TF' STO CL(SIGMA)
     FRMA FRMI - ABS 137 / TR ABS LOG 20 * 'ALOG(X)' 'S' STO FRMI 'X' STO
       << -> ST MB
         << WHILE FRMA X >= REPEAT X MB ->NUM ST 'X' STO+ END >> >> EVAL
       { 137 2 } ->ARRY STO(SIGMA) 1 2 COL(SIGMA) SCL(SIGMA) CLLCD DRW(SIGMA)
       20 GRID DGTIZ OUT >> >>
'MBOD' STO
              This is the calculus module for Bode Module plot.
 
<< PPAR LIST-> 4 DROPN C->R 3 ROLL C->R SWAP 4 ROLL 4 DUPN SWAP - ABS 68 /
   3 ROLLD - ABS 15 /
   << -> GAP YMA YMI XMI XMA XS YS
      << XMI XMA FOR X YMI YMA FOR Y X Y R->C PIXEL YS STEP NEXT
         YMI YMA FOR Y XMI XMA FOR X X Y R->C PIXEL XS STEP GAP STEP >> >>
   EVAL >>
'GRID' STO
              This is the grid plotter. It steps on decades for frequency axis
              and 20dB for gain.
 
<< PPAR LIST-> 4 DROPN LCD-> { (SIGMA)DAT (SIGMA)PAR PPAR X S } PURGE >>
'OUT' STO
              This is the exit routine. It eliminates all the work vars
              and leaves 'TF' for next evaluations of Transfer Function.
 
The only parms you need to pass to MBOD are the min. & max. freq. (in rad/sec)
expressed in decades.
 
For example if you need to evaluate the TF from 1e3 to 1e9 rad/sec., type in
1) The Transfer Function (in S)
2) 3 9 MBOD
 
I've included a DIGITZ to enable the evaluation of poles via graph.
 
With few modifies you can obtain the program for phase bode plots.
 
<< -> TR FRMI FRMA
   << TR 'TF' STO CL(SIGMA) 60 CF FRMA FRMI - ABS 137 / TR ARG 'I*ALOG(X)'
      'S' STO << -> ST MB << WHILE FRMA X >= REPEAT X MB ->NUM ST 'X' STO+
       END >> >> EVAL { 137 2 } ->ARRY STO(SIGMA) 1 2 COL(SIGMA) SCL(SIGMA)
       CLLCD DRW(SIGMA) 45 GRID DGTIZ OUT 60 SF >> >>
'PBOD' STO
          This is for phase evaluation, with a grid of 45 degrees on phase
          scale, and the usual decade division on freq. axis.
 
I've used the symbol (SIGMA) to indicate the relative greek letter, used
by the HP-28 to indicate the statistical operations.
 
Waiting for comments and suggests,
 
                                                 Alan Ford
 
 
P.S. I would be very happy if everyone would share with me infos on
     System Objects on HP-28 and hardware remarks and diagrams.
