	This is a very simple golf score card for the HP28C. It should
	work on a 28S too.

	To use it, enter the programs listed below then re-order the
	user keys so that TOFF, STRKE and HOLE are on the first page.

	To begin a game, press TOFF. This initialises the counters. As
	you take a stroke, press STRKE. This updates the score for
	that hole and the total for the round.

	As you move to the next hole press HOLE.

	You can view the score you had on any hole by pressing HOLE
	until the score for the hole you are interested in is displayed.
	Remember to return to the current hole if the round isn't
	finished yet.

	You can also use the calclator (to work out your winnings?)
	any time, the next press of TOFF, STRKE or HOLE will the
	restore the scorecard display.

	I don't play golf, so any hints for improvements and features
	will be welcome! I havn't included checksums, because all the
	'CHK' programs I've seen so far have the 28S-only syntax #0h
	in them, so you can't check you've typed them in right on a
	28C!

	Have fun.

	Alex Ballantyne,
	Hewlett Packard Ltd.
	Queensferry Telecoms. Div.
	South Queensferry,
	Scotland, U.K.

	alex@hpsqf.sqf.hp.com





	TOFF
	<< 1.00 19.00 FOR n 0.00		; Initialise store.
	NEXT 19.00 ->LIST			; (19th hole stores
	'SCORES' STO 1.00			;  the round total)
	'HOLENO' STO WRITE >>			; Display current score.

	STRKE
	<< SCORES HOLENO GET 1.00		; Increment score for
	+ SCORES SWAP HOLENO			; this hole.
	SWAP PUT 'SCORES' STO
	TOTUP WRITE >>				; Cal. round total & display

	HOLE
	<< HOLENO 1.00 + 'HOLENO'		; Increment current hole
	STO IF HOLENO 18.00 > 			; MOD 18.
	THEN 1.00 'HOLENO' STO
	END WRITE >>				; Display new hole.

	WRITE
	<< "Hole  >> " HOLENO ->STR		; Build a 3 line 
	+ 1.00 DISP "Score >> "			; display of current
	SCORES HOLENO GET ->STR +		; score.
	2.00 DISP "Total >> "
	SCORES 19.00 GET ->STR +
	3.00 DISP >>

	TOTUP
	<< SCORES LIST-> DROP2			; Calc. round total
	1.00 17.00 FOR h + NEXT			; from all the hole
	SCORES SWAP 19.00 SWAP			; scores.
	PUT 'SCORES' STO >>
