#! /bin/perl

$romlib = "/usr/local/lib/hp41c";       # default rom library
$outfile = 'bar.out';                   # default output file
$title = "HP 41-C Assembler";           # default title
unshift(INC,$romlib);
$DATE = `date`;

while ($_ = $ARGV[0], /^-/) {
	shift;
    last if /^--$/;
	/^-n/ && do {              # want null bytes
		++$nulls;
		next; };
	/^-l/ && do {              # want listing
		++$listing;
		next; };
	/^-o/ && do {              # specify output file
		die "asm41c: no file arg for -o"
			unless ($ARGV[0]);
		$outfile = shift;
		next; };
	/^-u/ && do {              # specfiy dir for user rom lib
		die "asm41c: no arg for -u"
			unless ($ARGV[0]);
		unshift(INC,shift);
		next; };
	/^-t/ && do {              # specify title
		die "asm41c: no title arg for -t"
			unless ($ARGV[0]);
		$title = shift;
		next; };
	/^-r/ && do {              # load rom
		die "asm41c: no rom name for -r"
			unless ($ARGV[0]);
		die "asm41c: can't find rom ".$ARGV[0]
			unless (do readrom($ARGV[0]));
		shift;
		next; };
	/^-X/ && do {              # load roms of 41-CX
		die "asm41c: can't load HP-41CX roms"
			unless (do readrom("CXextfcn") &&
				do readrom("CXtime"));
		next; };
	/^-I/ && do {              # load roms for IL support
		die "asm41c: can't load IL roms"
			unless (do readrom("ILcntl") &&
				do readrom("ILmass") &&
				do readrom("ILprinter"));
		next; };
	#default
	die "asm41c: unknown flag $_";
}

die "asm41c: can't find builtin ops file"
	unless (do "builtins");

$~ = 'line';
$^ = 'top';
open(OUTFILE,">$outfile");
if ($title) {print OUTFILE "title $title\n";}
do defsym();
			   # special \ intreps for strings
$specord{'-'} = 127;            # append char
$specord{'='} =  29;            # not equal char
$specord{'S'} = 126;            # sigma (can use '~' instead)
$specord{'M'} =  12;            # mu
$specord{'L'} =  13;            # angle char
$specord{'P'} = 123;            # pi    (can use '{' instead)
$specord{'A'} = 125;            # arrow char (can use '}' instead)

while (<>) {
	chop;
	$line = $_;
	$error = '';
	unless (/^[ \t]*$\|^\.\|^[ \t]*#/) {
		do display('',$_,"Non-directive",'');
		next;
	}
	/^\.rom\s+([^\s#]+)\s*(#.*)?$/ && do {
		$error = "Can't find rom '$rom'."
			unless (do readrom($1));
		do display('',$line,$error,'');
		next; };
	/^\.xrom\s+([^\s#]+)\s+(\d\d)\s+(\d\d)\s*(#.*)?$/ && do {
		$xrom{$1} = sprintf("%03d %03d",160+($2/4),64*($2%4)+$3);
		do display('',$line,'','');
		next; };
	/^\.title\s+([^#]*)(#.*)?$/ && do {
		$title = $1;
		do display('',$line,'','');
		print outfile "title $1\n";
		next; };
	/^\.page\s*(#.*)?$/ && do {
		$- = 0;         #force new page
		do display('',$line,'','');
		next; };
	/^\.prog(\s+private)?(\s+([^#]+))?(#.*)?$/ && do {
		$program = ($3) || "unnamed";
		$errcnt = 0;
		print OUTFILE "program$1 $program\n";
		do display('',$line,'','');
		$lineno = 0;
		$lastnum = $nulls;
		while (<>) {
			last if (/^\./);
			chop;
			/^\s*(#.*)?$/ && do { #blank or comment
				do display('',$_,'','');
				next; };
			do asm($_);
			$bytes = join(' ',@byt);
			do display(++$lineno,$_,$error,$bytes);
			print OUTFILE "$bytes\n";
		}
		$error = $errcnt ?
			"program: $program, errors: $errcnt.":'';
		do display('','',$error,'');
		print OUTFILE "end $program\n";
		$program = '';
		last unless (/^\./);
		redo; };
	/^\.define\s+([A-Za-z]\w+)\s+(\d+|[A-Za-z]\w+)\s*(#.*)?$/ && do {
		$name = $1;
		$val = do validarg($2);
		do display('',$_,$error,'');
		$defsymbol{$name} = do pad($val);
		next; };
	/^\.exec(\s+([^#]*))?(#.*)?$/ && do {
		print OUTFILE "exec $2\n";
		do display('',$line,'','');
		chop($line = <>);
		do asm($line);
		$bytes = join(' ',@byt);
		do display('',$line,$error,$bytes);
		print OUTFILE "$bytes\n";
		next; };
      /^\.string(\s+append)?\s+"(([^"]*\\")*.*)"(\s+([^#]*))?(#.*)?$/ && do {
		$str = $2;
		print OUTFILE "string$1 \"$str\" $5\n";
		do strbytes($str);
		if ($#byt > 14) {
			$error = "String too long -- truncated.";
			$#byt = 13;
		}
		$bytes = join(' ',@byt);
		print OUTFILE "$bytes\n";
		do display('',$line,$error,$bytes);
		next; };
    /^\.data\s+'([-+]?\d*\.?\d*([eE][-+]?\d*)?)'(\s+([^#]*))?(#.*)?$/ && do {
		$num = $1;
		$text = $4;
		print OUTFILE "data '$num' $text\n";
		do display('',$line,'','');
		next; };
	/^.bytes(\s+checksum)?\s+(\d+(\s+\d+)*)(\s+([^#]*))?(#.*)?/ && do {
		@byt = split(//,$2);
		print OUTFILE "bytes$1 $5\n";
		$checksum = $1;
		for $num (@byt) {
			$num = do pad($num % 256);
		}
		if ($#byt > ($checksum?14:15)) {
			$error = "Too many bytes -- Truncated";
			$#byt = ($checksum?14:15);
		}
		$bytes = join(' ',@byt);
		do display('',$line,$error,$bytes);
		print OUTFILE "$bytes\n";
		next; };
	/^\.clear\s+roms\s*(#.*)?$/ && do {
		reset 'x';
		do display('',$line,'','');
		next; };
	/^\.clear\s+names\s*(#.*)?$/ && do {
		reset 'd';
		do defsym();
		do display('',$line,'','');
		next; };
	/^\./ && do {
		# if we get to here we don't recognize it
		do display('',$_,"Unknown directive",'');
		next; };
	# default for blank line and/or comments
	do display('',$_,'','');
}
print "\f" if ($listing);
exit 0;

#
# end of main routine
#

format line =
# optional error message
~         @<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
	  $error;
#first six bytes, line number & start of line image
 ^<<<<<<<<<<<<<<<<<<<<<<<  @>>> ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 $bytes                  $lno $limage
#optional second six bytes & rest of line image
~^<<<<<<<<<<<<<<<<<<<<<<<           ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 $bytes                                 $limage
#optional last six bytes
~^<<<<<<<<<<<<<<<<<<<<<<<
 $bytes
.

format top =


 @<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< @>>>>>>>>>>>>>>>>>>>>>>>>>>>
 $title                                       $DATE
 @<<<<<<<<<<<<<<<<<<<<<<<<<<                                      Page @>>
 $program                                                              $%


.

sub readrom {
	local($romname) = @_;
	$romname .= ".rom" unless ($romname =~ /\.rom$/);
	do $romname;
}

sub pad {
	sprintf("%03d",pop(@_));
}

sub display {
	local($lno,$limage,$error,$bytes) = @_;
	++$errcnt if $error;
	if ($listing) {
		$lno = sprintf("%04d",$lno) if $lno;
		$error = "ERROR:     $error" if $error;
		write;
	} else {
		if ($error) {
			print stderr "ERROR: $error\n";
			print stderr "\t$limage\n";
		}
	}
}

sub strbytes {
	local($_) = @_;
	@byt = ();
	while (length($_)) {
		s/^\\(\d\d\d)(.*)$/$2/ && do {
			push(byt,do pad($1 % 256));
			next; };
		s/^\\x([\da-fA-F][\da-fA-F])(.*)$/$2/ && do {
			push(byt,do pad(hex($1)));
			next; };
		s/^\\(.)(.*)$/$2/ && do {
			push(byt, do pad($specord{$1} || ord($1)));
			next; };
		s/^(.)(.*)$/$2/ && do {
			push(byt,do pad(ord($1)));
			next; };
	}
}

sub numbytes {
	local($_) = @_;
	@byt = ();
	foreach (split(//)) {
		/[0-9]/ && (push(byt,do pad(16+$_)),next);
		/[Ee]/  && (push(byt,do pad(27))   ,next);
		/-/     && (push(byt,do pad(28))   ,next);
		/\./    && (push(byt,do pad(26))   ,next);
		# note '+' are ignored
	}
}

sub defsym {
# Predefined user defined symbols
$defsymbol{'A'} = 102; $defsymbol{'B'} = 103;
$defsymbol{'C'} = 104; $defsymbol{'D'} = 105;
$defsymbol{'E'} = 106; $defsymbol{'F'} = 107;
$defsymbol{'G'} = 108; $defsymbol{'H'} = 109;
$defsymbol{'I'} = 110; $defsymbol{'J'} = 111;
$defsymbol{'T'} = 112; $defsymbol{'Z'} = 113;
$defsymbol{'Y'} = 114; $defsymbol{'X'} = 115;
$defsymbol{'L'} = 116; $defsymbol{'M'} = 117;
$defsymbol{'N'} = 118; $defsymbol{'O'} = 119;
$defsymbol{'P'} = 120; $defsymbol{'Q'} = 121;
$defsymbol{'R'} = 122; $defsymbol{'a'} = 123;
$defsymbol{'b'} = 124; $defsymbol{'c'} = 125;
$defsymbol{'d'} = 126; $defsymbol{'e'} = 127;
}

sub validarg {
	local($val) = @_;
	$val = $defsymbol{$val} if ($val =~ /^[A-Za-z]/);
	if ($val eq '') {
		$error = "Undefined symbol -- 000 assumed.";
		$val = "000";
	} elsif ($val < 0 || $val > 127) {
		$error = "Arg out of range -- taken mod 128.";
		$val %= 128;
	};
	$val;
}

sub asm {
	local($_) = @_;
	@byt = ();
	$error = '';
	/^\s*'([-+]?\d*\.?\d*([eE][-+]?\d*)?)'\s*(#.*)?$/ && do {
		do numbytes($1);
		unshift(byt,"000") if ++$lastnum;
		return; };
	$lastnum = $nulls;
	/^\s*"(([^"]*\\")*.*)"\s*(#.*)?$/ && do {
		do strbytes($1);
		if ($#byt > 14) {
			$error = "String too long -- truncated.";
			$#byt = 14;
		}
		unshift(byt,do pad(241+$#byt));
		return; };
	/^\s*END\s*(#.*)?$/ && do {
		@byt = ("192","000","009");
		return; };
	/^\s*XROM\s+(\d\d)\s+(\d\d)\s*(#.*)?$/ && do {
		@byt = (do pad(160+($1/4)), do pad(64*($1%4)+$2));
		return; };
	/^\s*(STO|RCL|LBL)\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		($op,$val) = ($1,do validarg($2));
		if (($op eq "LBL" && $val > 14) || $val > 15) {
			@byt = ($twobyte{$op},do pad($val));
		} elsif ($op eq "STO") {
			@byt = (do pad(48+$val));
		} elsif ($op eq "RCL") {
			@byt = (do pad(32+$val));
		} else { # $op = "LBL"
			@byt = (do pad(1+$val));
		};
		return; };
	/^\s*LBL\s+"(([^"]*\\")*.*)"\s*(#.*)?$/ && do {
		do strbytes($1);
		unshift(byt,"192","000",do pad(242+$#byt),"000");
		return; };
	/^\s*GTO\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		$val = do validarg($1);
		if ($val > 14) {
			@byt = ("208","000",do pad($val));
		} else {
			@byt = (do pad(177+$val),"000");
		};
		return; };
	/^\s*GTO3\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		$val = do validarg($1);
		@byt = ("208","000",do pad($val));
		return; };
	/^\s*XEQ\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		$val = do validarg($1);
		@byt = ("224","000",do pad($val));
		return; };
	/^\s*(GTO|XEQ|W)\s+"(([^"]*\\")*.*)"\s*(#.*)?$/ && do {
		$op = (($1 eq "GTO") ? "029" : ($1 eq "W") ? "031" : "030");
		do strbytes($2);
		unshift(byt,$op,do pad(241+$#byt));
		return; };
	/^\s*(GTO|XEQ)\s+IND\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		($op,$val) = ($1,do validarg($2));
		@byt = ("174",do pad((($op eq "GTO")?0:128)+$val));
		return; };
	/^\s*BYTE\s+(\d+)\s*(#.*)?$/ && do {
		@byt = (do pad($1 % 256));
		return; };
	/^\s*([^'"#\s]+)\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		$op = $twobyte{$1};
		$val = do validarg($2);
		unless ($op) {
			$error .= "Undefined OP code -- RCL assumed.";
			$op = "144";
		};
		@byt = ($twobyte{$1},do pad($val));
		return; };
	/^\s*([^'"#\s]+)\s+IND\s+([A-Za-z]\w*|\d+)\s*(#.*)?$/ && do {
		$op = $twobyte{$1};
		$val = do validarg($2);
		unless ($op) {
			$error .= "Undefined OP code -- RCL assumed.";
			$op = "144";
		};
		@byt = ($op,do pad(128+$val));
		return; };
	/^\s*([^'"#\s]+)\s*(#.*)?$/ && do {
		$op = $single{$1};
		unless ($op) {
		    $op = $xrom{$1};
		    unless ($op) {
			$error = "Undefined OP code -- NULL assumed.";
			$op = "000";
		    };
		};
		@byt = ($op);
		return; };
	$error = "Syntax error.";
	$bytes = ''; # work around for join bug
	@byt = ();
}
