%%HP: T(3)A(D)F(.);
DIR
  deal
    \<< { } { } { } 1
1 1 1 0 0 0 15 100
0 \-> PH2 PH DH PP
PP2 DP X TOT TOT2
DTOT BET BNK NME
      \<<
        IFERR CRDT
1 GET
"Enter your name or 
Initial"
{ "" \Ga } INPUT DUP
'NME' STO POS 'X'
STO CLLCD
          IF X 0 \=/
          THEN CRDT
2 GET X GET 15 -
'BNK' STO CRDT 1
GET 1 X 1 - SUB
CRDT 1 GET X 1 +
CRDT 1 GET SIZE SUB
+ CRDT 2 GET 1 X 1
- SUB CRDT 2 GET X
1 + CRDT 2 GET SIZE
SUB + 2 \->LIST
'CRDT' STO
          END
          DO ERASE
PICT { # 71d # 27d
} "BET  BANK" 1
\->GROB REPL 0 'TOT'
STO 0 'DTOT' STO 0
'TOT2' STO { }
'PH2' STO { } 'PH'
STO { } 'DH' STO {
# 2d # 40d } { # 2d
# 25d } { # 2d # 2d
} 'DP' STO 'PP2'
STO 'PP' STO
            DO {
# 71d # 17d } {
# 89d # 25d } BOX {
# 90d # 17d } {
# 130d # 25d } BOX
PICT { # 0d # 55d }
BK REPL { # 0d # 0d
} PVIEW BET BNK
Mdsp 0 WAIT 'X' STO
              IF X
15.1 SAME
              THEN
IF 5 BNK < BET 995
< AND
THEN BET 5 + DUP
'BET' STO " " + BNK
5 - DUP 'BNK' STO
" " + Mdsp
END
              END
              IF X
16.1 SAME
              THEN
IF BET 15 \>=
THEN BET 5 - DUP
'BET' STO " " + BNK
5 + DUP 'BNK' STO
" " + Mdsp
END
              END
            UNTIL X
11.1 SAME
            END gc2
DUP PH + 'PH' STO
PP DUP { 11 -2 }
ADD 'PP' STO dsp
gc2 DUP DH + 'DH'
STO DP DUP { 11 -2
} ADD 'DP' STO dsp
gc2 DUP PH + 'PH'
STO PP DUP { 11 -2
} ADD 'PP' STO dsp
gc2 DH + 'DH' STO
DP { 2 2 } - DUP {
10 15 } ADD BOX PH
{ # 115d # 42d }
TOTAL 'TOT' STO
            IF TOT
21 \=/
            THEN
              DO 0
WAIT 'X' STO
CASE X 11.1 SAME
  THEN gc2 DUP PH +
'PH' STO PP DUP {
11 -2 } ADD 'PP'
STO dsp PH { # 115d
# 42d } TOTAL 'TOT'
STO
  END X 13.1 SAME
BNK BET > AND
  THEN BNK BET -
'BNK' STO BET 2 *
'BET' STO BET " " +
BNK " " + Mdsp 12.1
'X' STO gc2 DUP PH
+ 'PH' STO PP DUP {
11 -2 } ADD 'PP'
STO dsp PH { # 115d
# 42d } TOTAL 'TOT'
STO
  END X 14.1 SAME
  THEN
    IF PH SIZE 2
SAME PH 1 GET PH 2
GET SAME AND BNK
BET > AND
    THEN BNK BET -
'BNK' STO BET 2 *
'BET' STO BET " " +
BNK " " + Mdsp PICT
{ # 0d # 38d } "  "
3 \->GROB REPL PICT {
# 0d # 45d } "  " 3
\->GROB REPL PH 2 GET
PH2 + 'PH2' STO PH
1 GET { } + 'PH'
STO PH EVAL PP { 11
-2 } - dsp PH2 EVAL
PP2 dsp PP2 { 11 -2
} ADD 'PP2' STO
    END
  END
END
              UNTIL
X 12.1 SAME TOT 22
\>= OR
              END
              IF
PH2 SIZE 0 \=/
              THEN
DO 0 WAIT 'X' STO
  CASE X 11.1 SAME
    THEN gc2 DUP
PH2 + 'PH2' STO PP2
DUP { 11 -2 } ADD
'PP2' STO dsp PH2 {
# 115d # 30d }
TOTAL 'TOT2' STO
    END X 13.1 SAME
BNK BET 2 / > AND
    THEN BNK BET 2
/ - 'BNK' STO BET
1.5 * 'BET' STO BET
" " + BNK " " +
Mdsp 12.1 'X' STO
gc2 DUP PH2 + 'PH2'
STO PP2 DUP { 11 -2
} ADD 'PP2' STO dsp
PH2 { # 115d # 42d
} TOTAL 'TOT2' STO
    END
  END
UNTIL X 12.1 SAME
TOT2 22 \>= OR
END
              END
              IF
TOT2 0 \=/ TOT2 21 \<=
AND TOT 21 \<= OR
              THEN
DH 1 GET DP dsp DP
{ 11 -2 } ADD 'DP'
STO DH { # 115d
# 2d } TOTAL 'DTOT'
STO
WHILE DTOT 16 \<=
REPEAT gc2 DUP DH +
'DH' STO DP DUP {
11 -2 } ADD 'DP'
STO dsp DH { # 115d
# 2d } TOTAL 'DTOT'
STO
END
              END
TOT TOT2 DTOT 3
\->LIST
            ELSE
"BLKJK" TOT2 DTOT 3
\->LIST
            END 2
WAIT BET BNK CAL
'BNK' STO 'BET' STO
          UNTIL BNK
BET + 5 \<=
          END ERASE
"Better luck next time  LOSER!!"
\-> l
          \<< 0 8
            FOR n
PICT { # 0d # 7d }
n * l 1 \->GROB REPL
            NEXT 3
WAIT ERASE
          \>>
        THEN ERASE
CLEAR
          IF BET
BNK + 115 >
          THEN NME
CRDT 1 GET + BET
BNK + CRDT 2 GET +
2 \->LIST 'CRDT' STO
          ELSE
ERASE {
"THIS GAME WAS WRITTEN BY"
"SAM BEHASHTEI IN THE 2ND YEAR OF"
"ELECTRICAL ENGINEERING AT THE"
"UNIVERSITY OF WESTERN ONTARIO."
"IF YOU HAVE ANY SUGGESTIONS"
"PLEASE E-MAIL ME AT:"
"PNKPNTR@EXECULINK.COM"
"    " "ENJOY!" } \->
l
            \<< 0 8
              FOR n
PICT { # 0d # 7d }
n * l n 1 + GET 1
\->GROB REPL
              NEXT
0 WAIT ERASE
            \>>
          END
        END
      \>>
    \>>
  CAL
    \<< 1 1 1 0 \-> LST
BET BNK P1 P2 D
BET2
      \<< LST EVAL
'D' STO 'P2' STO
'P1' STO
        IF P1
"BLKJK" SAME
        THEN BET
1.5 * BNK + 'BNK'
STO
        ELSE
          IF P2 0 \=/
          THEN BET
2 / DUP 'BET' STO
'BET2' STO
          END
          IF D 21 >
          THEN BET
BNK + 'BNK' STO
BET2 BNK + 'BNK'
STO
          ELSE
            IF D P1
< P1 21 \<= AND
            THEN
BET BNK + 'BNK' STO
            END
            IF P1
21 >
            THEN
BNK BET - 'BNK' STO
            END
            IF P2
21 >
            THEN
BNK BET2 - 'BNK'
STO
            END
            IF D P1
> D 21 \<= AND
            THEN
BNK BET - 'BNK' STO
            END
            IF D P2
< P2 21 \<= AND
            THEN
BET2 BNK + 'BNK'
STO
            END
            IF D P2
> P2 0 \=/ AND
            THEN
BNK BET2 - 'BNK'
STO
            END
          END
        END
        IF P2 0 \=/
        THEN BET 2
* 'BET' STO
        END
        IF BNK 10 \<=
        THEN BET 10
- BNK + 'BNK' STO
10 'BET' STO
        END BET BNK
      \>>
    \>>
  Mdsp
    \<< \-> BET BANK
      \<< PICT {
# 73d # 19d } BET 1
\->GROB REPL PICT {
# 92d # 19d } BANK
1 \->GROB REPL
      \>>
    \>>
  TOTAL
    \<< { "" "2" "3"
"4" "5" "6" "7" "8"
"9" "10" "J" "Q"
"K" "A" } { } \->
HAND P DECK X
      \<< PICT P P {
2 2 } - DUP { 16 12
} ADD BOX 1 HAND
SIZE
        FOR N DECK
HAND N GET POS 'P'
STO
          IF P 10 >
          THEN 10
            IF P 14
SAME
            THEN 1
+
            END 'P'
STO
          END P
        NEXT HAND
SIZE \->LIST \GSLIST
'X' STO
        IF X 21 >
        THEN HAND
"A" POS
          IF 0 \=/
          THEN 1
HAND SIZE
            FOR N
HAND N GET
              IF
"A" SAME X 21 > AND
              THEN
X 10 - 'X' STO
              END
            NEXT
          END
        END
        IF X 21 ==
HAND SIZE 2 SAME
AND
        THEN 1 3
          FOR n
PICT { # 25d # 4d }
{ 0 } n + ADD
"BlackJack!!!" 3
\->GROB GOR
          NEXT 2
WAIT
        END X 3
\->GROB REPL X
      \>>
    \>>
  gc2
    \<< { "2" "3" "4"
"5" "6" "7" "8" "9"
"10" "J" "Q" "K"
"A" } RAND 13 *
CEIL GET
    \>>
  dsp
    \<< \-> CH P
      \<< P { 2 2 } -
DUP { 10 15 } ADD
BOX PICT P { 0 6 }
ADD {
GROB 7 6 80C1F7E380C1
GROB 5 6 40E0F1F140E0
GROB 5 6 40E0F1F1E040
GROB 5 5 A0F1F1E040
} RAND 4 * CEIL GET
REPL PICT P CH 1
\->GROB REPL
      \>>
    \>>
  BK
GROB 131 7 EFFFF8FFFF3EFFFF8FFFF3EFFFF8FFFF30FA2EFD36766FCCEFD72A36FBF8FDFF1F70FA6FFDBAAB7FAAEFDBBA77FBFEFDFFDF70F86FFD32677FACEFD73A77F0E8FD3C1F70FA6FFDBBEE6FAAEFDFAB77FBFBFDFF7F70FA6FFDBB237FCC8FD3B367FBF8FDFF1F70EFFFF8FFFF3EFFFF8FFFF3EFFFF8FFFF30
  CRDT { { "SAM" }
{ 235 } }
  PPAR {
(-6.5,-3.1)
(6.5,3.2) X 0 (0,0)
FUNCTION Y }
END
