From: mozgy@danielle.mozgy.hr (Mario Mikocevic Mozgy)
Newsgroups: comp.sys.hp48
Subject: [SOURCE] Christmas Time
Date: 26 Dec 1998 22:06:44 GMT
Organization: HiNet
Lines: 1607
Message-ID: <slrn78angk.vu.mozgy@danielle.mozgy.hr>
Reply-To: mario.mikocevic@sk.tel.hr
NNTP-Posting-Host: al4-p65-zg.tel.hr
Mime-Version: 1.0
Content-Type: text/plain; charset=US-ASCII
Content-Transfer-Encoding: 7bit
X-Trace: as102.tel.hr 914710004 648 195.29.230.193 (26 Dec 1998 22:06:44 GMT)
X-Complaints-To: news@tel.hr
NNTP-Posting-Date: 26 Dec 1998 22:06:44 GMT
Keywords: Game
User-Agent: slrn/0.9.5.3 (UNIX)
Xref: republic.btigate.com comp.sys.hp48:20219

Well, it's christmas time ...

In my language it's called `Cestit Bozic` .




*****************************************************************************
* Modulname:	Invaders
* Modultype:	User level secondary
* Dest.Comp.:	HP48
* Language:	System RPL & Machine Code
* Author:	Mario Mikocevic Mozgy, Stj. Rozankovica 36. 44000 SISAK CROATIA
* Copyright:	GPL
* Interface:	INVADERS	( % --> )
* Description:	Space Invaders Game
* Edition History :
*	1.0	02-10-1991	MMM	Release
*	1.1	09-11-1991	MMM	Fixed clock problems
*	1.2	05-03-1993	MMM	Source revision for SASM
*	2.0	15-07-1993	MMM	GX revision M
*****************************************************************************
*  Usage : Cursors move left & rigth
*          Dot key fires
*  Note  : 'InvdPAR' is reserved variable for parameters
*  		    first five (5) nibbles are score
*			 each next pair of nibbles is movement description
******************************************************************************


    ASSEMBLE
	NIBASC /HPHP48-D/
DSKTOP_gx EQU #806F8

    RPL
::
   CK1&Dispatch ONE
   ::
      COERCE		( 11: LEVEL )
      TOTEMPOB		( NEWOB! )
      '			( PUT D0 ON DSTK )
      ID InvdPAR
      Sys@		( RCL FROM HOME )
      NOT		( REVERSE OK,W )
      IT		( IF OK DONOTHING ELSE SKIPONE )
      ::
         HXS 10 0000091840800000	( DEFAULT )
         ' ID InvdPAR SWAP OVER
         CreateVarHome			( CREATE VAR IN HOME )
         Sys@ DROP
      ;			( 10: HIGH SCORE & MOVEMENT )
      HXS 32 25552322277471774747557447174761757742117575775747
			( 9: DIGIT IMAGE )
*      HXS 24 FFFFFF6004803002401A0100040010004001
    ASSEMBLE
      CON(5)	=DOHSTR
	CON(5)	41
	NIBHEX FFF	( TMP SPEED )
	NIBHEX FFF
	NIBHEX 600	( LEVEL 0 SPEED )
	NIBHEX 480
	NIBHEX 300
	NIBHEX 240
	NIBHEX 1A0
	NIBHEX 100
	NIBHEX 040
	NIBHEX 010
	NIBHEX 004
	NIBHEX 001
*			( 8: SPEED FOR LEVELS )
    RPL
      TOTEMPOB
    ASSEMBLE
      CON(5)	=DOHSTR
	CON(5)	200
	NIBHEX 0      ( REPEAT NIBBLE )
	NIBHEX 03
	NIBHEX 80D001D081D002D082D003D083D004D084D005D085D006D0
	NIBHEX 804101418141024182410341834104418441054185410641
	NIBHEX 80B101B181B102B182B103B183B104B184B105B185B106B1
	NIBHEX 802201228122022282220322832204228422052285220622
*			( 7: ENEMY COUNT & COORDS START )
    RPL
      DUP TOTEMPOB	( 6: ENEMY COUNT & COORDS )
    ASSEMBLE
      CON(5)	=DOHSTR
	CON(5)	145
	NIBHEX 000083004400C700440028000000
	NIBHEX 000083004400C700440082000000
	NIBHEX 000001000100C7006C00EF000000
	NIBHEX 000083004400EF00440083000000
	NIBHEX 0000000000000000000000000000
*			( 5: ENEMY IMAGES )
      CON(5)	=DOHSTR
	CON(5)	153
	NIBHEX 66737A275020
	NIBHEX 11551AA05020
	NIBHEX 21537EA678F0
	NIBHEX 41551AA45C81
	NIBHEX 36757A275CF1
	NIBHEX 0381C0C0603
	NIBHEX 87C3E1E1F87
	NIBHEX CFFFF3FFFFF
	NIBHEX CFFFF3FFFFF
	NIBHEX CFFFF3FFFFF
	NIBHEX CFFFF3FFFFF
	NIBHEX CFFFF3FFFFF
	NIBHEX CFFFF3FFFFF
*			( 4: PICTURE DEFINITION )
    RPL
      KILLGDISP	SIXTYFOUR #83
      MAKEGROB GROB>GDISP GBUFF	( 3: MAIN PICTURE )
    ASSEMBLE
      CON(5)	=DOHSTR
	CON(5)	143
	NIBHEX 043000		(  RMMRKK )
	NIBHEX 0000000000	(  YYXXAAAAAB )
	NIBHEX C0		( GUN COUNT )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
	NIBHEX 0000000000	( GUNS YYXXAAAAAB )
    RPL
      TOTEMPOB			( 2: SPRITE COORDS )
      HXS 17 00000FFFFFFFFFFFFFFFFFF
*	DHEX $00000			( SCORE )
*	DHEX $FFFFFFFFFFFFFFFFFF	( TIME PASSED )
      TOTEMPOB		( 1: SCORE , TIME )
      CODE
        GOSBVL =SAVPTR
        P= 0
        D1=(5) #11F
        A=DAT1 1
        LCHEX #8
        ?A=C P
        GOYES START
	GOVLNG =GETPTRLOOP
START   SETHEX
        ST=0 #F
        INTOFF
	A=0 W
	GOSBVL #1A96	( FIXING CLOCK TO MAX )
	ST=0 0
	C=0 A
	GOSBVL #1ABD
	GOSBVL #148C
	P= 0
	SETHEX
        GOSUB MKLCD
        GOSUB LCDD
        ST=0 0		( INVADERS LOOK )
        ST=1 1		( DIRECTION OF INVADERS )
        ST=0 2		( DIRECTION OF MYSHIP )
        ST=0 3		( SCORE TO SET )
        ST=0 4		( SCORE TO SET - BSHIP OR INVADERS )
        ST=0 5		( GUN_LESS REQUEST )
	ST=0 6		( BONUS SHIP )
*		  ( GOSUBL VISCORE )
        D0=(2) #1
        GOSUB GETLV
        D0=D0+ 10
        LCHEX #2
        DAT0=C P
        GOSUBL VIHIGH
        GOSUBL VISHIP
        D0=(2) #A
        GOSUB GETLV
        D0=D0+ 5
        A=DAT0 A
        C=0 A
        DAT0=C A
        LCHEX #A
        ?C>A A
	GOYES ST01
        ACEX A
ST01    A=A+1 A
        A=A+1 A
        C=A A
        A=A+A A
        C=C+A A
        D0=(2) #7
        GOSUB GETLV
        D0=D0+ 10
        AD0EX A
        B=A A
        C=C+A A
        D0=C A
        C=0 A
        C=DAT0 X
        A=B A
        D0=A A
        DAT0=C X
        D0=D0+ 3
        DAT0=C X
        P= 0
        D0=(5) =DSKTOP_gx
        A=DAT0 A
        D0=A A
        C=DAT0 A
        D0=C A
        D0=D0+ 15
        D1=(5) =TIMER2
        A=DAT1 8
        DAT0=A 8
        D0=D0+ 8
        DAT0=A 8
ST00    GOSUB MVENM    ( MOVE ENEMY )
        GOSUB ENEMY    ( DRAW ENEMY )
        GOSUB BSHIP
        GOSUBL GETGUN
        GOSUBL MVGUN2
        ?ST=1 3
	GOYES ST11
	GOTO ST03
ST11    P= 0
        C=0 A
        LCHEX #2
        ?ST=0 4
	GOYES ST04
        LCHEX #29
ST04    D0=(5) =DSKTOP_gx
        A=DAT0 A
        D0=A A
        A=DAT0 A
        D0=A A
        D0=D0+ 10
        A=DAT0 A
        A=A+C A
        DAT0=A A
        ST=0 3
        ST=0 4
	LCHEX #001F4
        ?C>A A
	GOYES ST08
	LCHEX #320
	?ST=1 6
	GOYES ST09
	?C<A A
	GOYES ST08
	ST=1 6
	GONC ST10
ST09	?C>A A
	GOYES ST08
	?ST=0 6
	GOYES ST08
	ST=0 6
ST10	D0=(2) #1
        GOSUB GETLV
        D0=D0+ 10
        C=DAT0 P
        C=C+1 P
        DAT0=C P
        GOSUBL VISHIP
ST08    GOSUBL VISCORE
ST03    D1=(5) =DSKTOP_gx
        C=DAT1 A
        D1=C A
        C=DAT1 A
        D1=C A
        D1=D1+ 15
        D0=(2) #7
        GOSUB GETLV
        D0=D0+ 10
        A=0 W
        A=DAT0 X
        D0=(5) =TIMER2
        R0=A W
        C=0 W
ST06    C=DAT1 8
        D1=D1+ 8
        B=C W
        C=DAT1 8
        D=C W
        D1=D1- 8
        C=0 W
        LCHEX #80
        B=B-A W
        ?C>A W
	GOYES ST02
        C=C-D W
        C=-C W
        ?B>C W
	GOYES ST02     
        P= 7
ST05    A=DAT0 8
        ?C<A WP
	GOYES ST05
        P= 0
        AD1EX A
        R3=A W
        GOSUB MOVE
        A=R3 W
        D1=A A
        D0=(5) =TIMER2
        C=0 W
        C=DAT0 8
        D1=D1+ 8
        DAT1=C 8
        D1=D1- 8
        A=R0 W
        GOTO ST06
ST02    P= 7
ST07    A=DAT0 8
        ?A>B WP
	GOYES ST07
        P= 0
        AD1EX A
        R3=A W
        GOSUB MOVE
        A=R3 W
        D1=A A
        D0=(5) =TIMER2
        C=DAT0 8
        DAT1=C 8
        D1=D1+ 8
        DAT1=C 8
        GOTO ST00

MOVE    GOSUB MVGUN
        D0=(2) #9
        GOSUB GETLV
        D0=D0+ 15
        AD0EX A
        R4=A W
        A=0 W
        GOSBVL =GetHardKey
        ?ABIT=0 0
	GOYES MV2
        C=RSTK A
        GOTO ENDGAME
MV2     ?A=0 W
	RTNYES
	C=R4 W
        D0=C A
        C=A W
        D=C W
        C=DAT0 1
        P=C 0
        D0=D0+ 1
        C=DAT0 P
        D0=D0+ 1
        C=C&A P
        ?C=0 P
	GOYES MV0
        ST=1 2
        P= 0
        GOSUB MYSHIP
        C=D W
        A=C W
        C=R4 W
        D0=C A
        D0=D0+ 2
MV0     C=DAT0 1
        P=C 0
        D0=D0+ 1
        C=DAT0 P
        D0=D0+ 1
        C=C&A P
        ?C=0 P
	GOYES MV1
        ST=0 2
        P= 0
        GOSUB MYSHIP
        C=D W
        A=C W
        C=R4 W
        D0=C A
        D0=D0+ 4
MV1     C=DAT0 1
        P=C 0
        D0=D0+ 1
        C=DAT0 P
        D0=D0+ 1
        C=C&A P
        ?C=0 P
	GOYES MV3
        P= 0
        GOTO MKGUN
MV3     P= 0
        RTNCC

ENDGAME GOSUB RMVLCD
        D0=(5) =DSKTOP_gx
        A=DAT0 A
        D0=A A
        A=DAT0 A
        D0=A A
        D0=D0+ 10
        C=DAT0 A
        D0=(2) #A
        GOSUB GETLV
        D0=D0+ 5
        DAT0=C A
        D0=(2) #9
        GOSUB GETLV
        D0=D0+ 10
        A=DAT0 A
        ?C<A A
	GOYES ENDG0
        DAT0=C A
ENDG0   A=0 W
	C=0 W
	GOSBVL =GetHardKey
	?A#0 W
	GOYES ENDG0
ENDG1   GOSBVL =AllowIntr
        P= 0
	GOVLNG =GETPTRLOOP

MVENM   D0=(2) #5
        GOSUB GETLV
        D0=D0+ 10
        C=DAT0 P
        C=C-1 P
        DAT0=C P
        RTNNC
        D0=D0+ 1
        CD0EX A
        D0=C A
        D=C A
        A=DAT0 B
        B=A B
        D0=D0+ 2
        LCHEX #02
        ?ST=0 1
	GOYES MV00
        LCHEX #78
MV00    A=DAT0 B
        ?A=C B
	GOYES MV01
        D0=D0+ 4
        B=B-1 B
        ?B#0 B
	GOYES MV00
        C=D A
        D0=C A
        A=DAT0 B
        B=A B
        D0=D0+ 2
MV03    C=DAT0 B
        C=C+1 B
        ?ST=1 1
	GOYES MV02
        C=C-1 B
        C=C-1 B
MV02    DAT0=C B
        D0=D0+ 4
        B=B-1 B
        ?B#0 B
	GOYES MV03
        ?ST=0 0
	GOYES MV06
        ST=0 0
        RTN
MV06    ST=1 0
        RTN
MV01    C=D A
        D0=C A
        A=DAT0 B
        B=A B
        ?ST=0 1
	GOYES MV05
        ST=0 1
        GONC MV04
MV05    ST=1 1
MV04    D0=D0+ 4
        A=DAT0 B
        A=A+1 B
        DAT0=A B
        B=B-1 B
        ?B#0 B
	GOYES MV04
        LCHEX #34
        ?C<A B
	GOYES END
        RTNCC

END     C=RSTK A
        GOTO ENDGAME

MKLCD   D0=(2) #2
        GOSUB GETLV
        D0=D0+ 10
        D0=D0+ 10
        AD0EX A
        D0=A A
        D1=A A
        A=0 W
        C=0 A
        LCHEX #87
MKL0    DAT0=A W
        D0=D0+ 16
        C=C-1 A
        GONC MKL0
        D1=D1+ 1
        D0=(2) #3
        GOSUB GETLV
        D0=D0+ 10
        C=0 A
        LCHEX #4
MKL1    A=DAT0 5
        DAT1=A 5
        D0=D0+ 5
        D1=D1+ 15
        A=DAT0 4
        DAT1=A 4
        D0=D0+ 4
        D1=D1+ 13
        A=DAT0 3
        DAT1=A 3
        D0=D0+ 3
        D1=D1+ 6
        C=C-1 A
        GONC MKL1
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 1
        A=0 A
        A=A-1 A
        C=0 A
        LCHEX #5
MKL2    DAT1=A A
        D1=D1+ 5
        C=C-1 A
        GONC MKL2
        DAT1=A 3
        LCHEX #00578
        AD1EX A
        C=C+A A
        D1=C A
        C=0 A
        LCHEX #7
MKL3    A=DAT0 6
        DAT1=A 6
        D0=D0+ 6
        D1=D1+ 8
        A=DAT0 5
        DAT1=A 5
        D0=D0- 6
        D1=D1+ 7
        A=DAT0 6
        DAT1=A 6
        D0=D0+ 6
        D1=D1+ 8
        A=DAT0 5
        DAT1=A 5
        D0=D0+ 5
        D1=D1+ 11
        C=C-1 A
        GONC MKL3
        ST=1 2
        GOTO MYSHIP

LCDD    D0=(2) #2
        GOSUB GETLV
        D0=D0+ 15
        D0=D0+ 5
        CD0EX A
        A=C A
        D0=(5) #100
        ?CBIT=0 0
	GOYES LCDD0
        LCHEX #C
        DAT0=C 1
        LCHEX #FFE
        D0=(2) #25
        DAT0=C X
        GOTO LCDD1
LCDD0   D0=(2) #25
        C=0 A
        DAT0=C X
LCDD1   D0=D0- 5
        DAT0=A A
        D0=D0+ 8
        LCHEX #BF
        DAT0=C B
        RTNCC

ENEMY   D0=(2) #4  ( 5: ENEMY IMAGES )
        GOSUB GETLV
        D0=D0+ 10
        ?ST=0 0
	GOYES LP01
        D0=D0+ 16
        D0=D0+ 12
LP01    AD0EX A
        AD1EX A
        D0=(2) #5  ( 6: ENEMY COORDS )
        GOSUB GETLV
        D0=D0+ 10
        C=DAT0 P
        C=C+1 P
        RTNNC
        LCHEX #2
        DAT0=C P
        D0=D0+ 1
        C=DAT0 B
        D=C B
        D0=D0+ 2
LP10    C=0 A
        C=DAT0 4
        AD0EX A
        R0=A W
        GOSUB SPRITE
        A=R0 W
        D0=A A
        D0=D0+ 4
        D=D-1 B
        ?D#0 B
	GOYES LP10
        RTNCC

RMVLCD  D0=(5) #8068D	( #7050E )
        D1=(5) #120
        C=DAT0 A
        DAT1=C A
        D0=D0+ 5
        D1=D1+ 5
        C=DAT0 X
        DAT1=C X
        D0=D0+ 8
        D1=D1+ 3
        C=DAT0 B
        DAT1=C B
        LCHEX #8
        D1=(2) #00
        DAT1=C 1
        RTNCC

SPRITE  D0=(2) #2  ( 3: PICTURE POINTER )
        GOSUB GETLV ( D SAVED, R1 TOUCHED )
        D0=D0+ 10    ( D1 = SPRITE IMAGE POINTER )
        D0=D0+ 10    ( C = XXYY )
        P= 4
        LCHEX #0
        P= 0
        B=C A
        CSR A
        CSR A
        C=C+C A
        A=C A
        ASL A
        A=A+C A
        CD0EX A
        A=A+C A
        C=0 A
        C=B B
        CSRB.F B
        CSRB.F B
        A=A+C A
        D0=A A
        A=0 A
        A=B B
        LCHEX #03
        A=A&C B
        R1=A.F B
        LCHEX #1FF
LP05    ?A=0 B
	GOYES LP04
        A=A-1 B
        C=C+C X
        GOTO LP05
LP04    C=-C-1 X
        B=C X
        P= 10
LP06    A=R1.F B
        C=DAT1 X
LP03    ?A=0 B
	GOYES LP02
        C=C+C X
        A=A-1 B
        GOTO LP03
LP02    A=DAT0 X
        A=A&B X
        A=A!C X
        DAT0=A X
        A=R1.F B
        D1=D1+ 4
        D0=D0+ 16
        D0=D0+ 16
        D0=D0+ 2
        P=P+1
        GONC LP06
        D1=D1- 16
        D1=D1- 8
        RTNCC

GETLV   RSTK=C A        ( IN D0 -> LEVEL )
        CD0EX A         ( DESTROYED A,D0 )
        P= 2
        LCHEX #000
        P= 0
        A=C A
        C=C+C A
        C=C+C A
        C=C+A A
        D0=(5) =DSKTOP_gx
        A=DAT0 A
        C=C+A A
        D0=C A
        C=DAT0 A
        D0=C A
        C=RSTK A
        RTNCC

RMVENM  ?C=0 B
	RTNYES
	D=C A
        C=0 A
        LCHEX #2E
        GOSUBL BPR
        D0=(2) #5
        GOSUB GETLV
        D0=D0+ 11
        C=DAT0 B
        B=C A
        D0=(2) #1
        GOSUB GETLV
        D0=D0+ 10
        D0=D0+ 16
        C=0 A
        C=DAT0 B
        C=C+CON A,5
        ?B>C B
	GOYES RM05
        ST=1 5
RM05    C=D A
        D0=(2) #7
        GOSUB GETLV
        D0=D0+ 10
        A=0 A
        A=DAT0 X
        B=A A
        BSR A
        BSRB.F A
        A=A-B A
        GOC RM04
        DAT0=A X
RM04    D0=(2) #5    ( C = ENEMY TO REMOVE )
        GOSUB GETLV
        D0=D0+ 11
        CD0EX A
        D=C A
        CD0EX A
        A=DAT0 B
        ?C>A B
	RTNYES
	D0=D0+ 2
RM00    D0=D0+ 4
        A=A-1 B
        C=C-1 B
        ?C#0 B
	GOYES RM00
        D0=D0- 4
        C=DAT0 4
        B=C A
        D0=D0+ 4
RM02    ?A=0 B
	GOYES RM01
        C=DAT0 4
        D0=D0- 4
        DAT0=C 4
        D0=D0+ 8
        A=A-1 B
        GOTO RM02
RM01    C=D A
        D0=C A
        A=DAT0 B
        A=A-1 B
        ?A=0 B
	GOYES RM03
        DAT0=A B
        C=B A
        GOTO SH99
RM03    C=RSTK A
        ST=1 3
        GOTO ENDLEV

BSHIP   D0=(2) #1
        GOSUB GETLV
        D0=D0+ 14
        A=DAT0 B
        ?A#0 B
	GOYES SH00
        D1=(5) #104
        A=0 A
        A=DAT1 4
        LCHEX #0FFF0
        ?C>A A
	RTNYES
	LCHEX #0701
SH03    DAT0=C B
        D0=(2) #4
        GOSUB GETLV
        CD0EX A
        ACEX A
        LCHEX #0005E
SH04    A=A+C A
        D1=A A
        C=0 A
        LCHEX #AF
        GOSUBL BPR
        CD0EX A
        GOTO SPRITE
SH00    D0=D0- 1
        C=DAT0 P
        C=C-1 P
        DAT0=C P
        RTNNC
        LCHEX #1
        DAT0=C P
        D0=D0+ 1
        LCHEX #0780
        A=A+1 B
        ?C<A B
	GOYES SH02
        C=A B
        GOTO SH03
SH02    A=C A
        LCHEX #00
        DAT0=C B
        C=A A
SH99    D0=(2) #4
        GOSUB GETLV
        A=C A
        AD0EX A
        LCHEX #0007A
        GOTO SH04

MYSHIP  D0=(2) #1      ( D SAVED, R1 TOUCHED )
        GOSUB GETLV
        D0=D0+ 11
        A=DAT0 B
        ?ST=0 2
	GOYES MS00
        A=A-1 B
        LCHEX #3A01
MS01    ?A=C B
	RTNYES
	DAT0=A B
        C=A B
        D0=(2) #4
        GOSUB GETLV
        CD0EX A
        A=C A
        LCHEX #00046
        C=C+A A
        D1=C A
        CD0EX A
        GOTO SPRITE
MS00    A=A+1 B
        LCHEX #3A79
        GOTO MS01

MKGUN   D0=(2) #1     ( ALL SCREWED )
        GOSUB GETLV
        D0=D0+ 16
        C=0 A
        C=DAT0 B
        ?C#0 B
	RTNYES
	LCHEX #38
        DAT0=C B
        D0=D0- 5
        C=DAT0 B
        C=C+CON B,4
        D0=D0+ 7
        DAT0=C B
        CD0EX A
        D=C A
        CD0EX A
        D0=(2) #2
        GOSUB GETLV
        B=C A
        A=C A
        LCHEX #00784
        ASRB.F A
        ASRB.F A
        C=C+A A
        AD0EX A
        A=A+C A
        D1=A A
        C=D A
        D0=C A
        D0=D0+ 2
        DAT0=A A
        D0=D0+ 5
        LCHEX #03
        B=B&C B
        A=0 A
        A=A+1 A
MK11    B=B-1 B
        GOC MK10
        A=A+A A
        GONC MK11
MK10    DAT0=A 1
        C=DAT1 P
        C=C!A P
        DAT1=C P
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        C=DAT1 P
        C=C!A P
        DAT1=C P
        RTN        

MVGUN   D0=(2) #1
        GOSUB GETLV
        D0=D0+ 16
        A=DAT0 B
        ?A=0 B
	RTNYES
	GOTO GUN

MVGUN2  D0=(2) #1
        GOSUB GETLV
        D0=D0+ 11
        C=DAT0 B
        B=C A
        D0=D0+ 15
        C=DAT0 B
        ?C=0 B
	RTNYES   
        D=C A
        D0=D0+ 2
MG01    A=DAT0 4
        ?A=0 B
	GOYES MG02
        GOSUB GUNTWO
MG02    D0=D0+ 10
        D=D-1 B
        ?D#0 B
	GOYES MG01
        ?ST=0 5
	RTNYES
	D0=(2) #1
        GOSUB GETLV
        D0=D0+ 10
        D0=D0+ 16
        C=0 A
        C=DAT0 B
        D=C A
        C=C-CON A,3
        RTNC
        AD0EX A
        D0=A A
        B=A A
        D0=D0+ 2
        C=D A
        C=C-1 A
MG04    A=DAT0 B
        D0=D0+ 10
        ?A=0 B
	GOYES MG03
        C=C-1 A
        GONC MG04
        RTNCC
MG03    ?C=0 A
	GOYES MG05
        A=DAT0 10
        D0=D0- 10
        DAT0=A 10
        D0=D0+ 10
        D0=D0+ 10
        C=C-1 A
        GOTO MG03
MG05    ST=0 5
        A=B A
        D0=A A
        A=DAT0 B
        C=0 A
        LCHEX #2
        A=A-1 B
        ?C>=A B
	RTNYES
	DAT0=A B
        RTNCC

GETGUN  D0=(5) #104
        A=0 A
        A=DAT0 4
        LCHEX #04000
        ?C>A A
	RTNYES
	D0=(2) #1
        GOSUB GETLV
        D0=D0+ 16
        D0=D0+ 10
        A=DAT0 B
        ?A=0 B
	RTNYES
	A=A-1 A
        B=A A
        D0=D0+ 2
GG1     A=DAT0 B
        ?A=0 B
	GOYES GG0
GG2     D0=D0+ 10
        B=B-1 B
        GONC GG1
        RTNCC
GG0     AD0EX A
        AD1EX A
        D0=(2) #5
        GOSUB GETLV
        D0=D0+ 11
        A=0 A
        A=DAT0 B
        ?A#0 B
	GOYES GG3
        AD1EX A
        AD0EX A
        GONC GG2
GG3     D0=D0+ 4
        B=A A
        A=A-1 A
        ?A=0 B
	GOYES GG4
        CD0EX A
        D=C A
        D0=(5) #105
        C=0 A
        C=DAT0 B
        D0=(2) #38
        A=DAT0 B
        C=C&A B
        A=B A
        A=A-1 A
        CDEX A
        D0=C A
        CDEX A
GG6     ?C<=A B
	GOYES GG5
        CSRB.F B
        GOTO GG6
GG5     D0=D0- 4
GG7     D0=D0+ 4
        B=B-1 A
        C=C-1 A
        GONC GG7
GG13    ?B=0 B
	GOYES GG4
        D0=D0- 2
        CD0EX A
        D0=C A
        D=C A
        A=DAT0 B
GG14    D0=D0+ 4
        C=DAT0 B
        ?A#C B
	GOYES GG12
        D0=D0+ 2
        B=B-1 A
        GOTO GG13
GG12    B=B-1 A
        ?B#0 B
	GOYES GG14
        C=D A
        D0=C A
        D0=D0+ 2
GG4     C=0 A
        C=DAT0 B
        C=C+CON B,4
        DAT1=C B
        D0=D0- 2
        A=0 A
        A=DAT0 B
        A=A+CON B,4
        D1=D1+ 2
        DAT1=A B
        D1=D1+ 2
        C=C+C A
        D=C A
        CSL A
        C=C+D A
        ACEX A
        D=C A
        CSRB.F A
        CSRB.F A
        C=C+A A
        D0=(2) #2
        GOSUB GETLV
        D0=D0+ 15
        D0=D0+ 5
        AD0EX A
        C=C+A A
        DAT1=C A
        D1=D1+ 5
        LCHEX #03
        C=C&D B
        A=0 A
        A=A+1 A
GG10    C=C-1 B
        GOC GG9
        A=A+A A
        GONC GG10
GG9     DAT1=A 1
        RTNCC

GUN     D0=D0+ 4     ( R2 TOUCHED )
        C=DAT0 A
        D1=C A
        D0=D0+ 5
        A=DAT0 S
        D1=D1- 16
        D1=D1- 16
        D1=D1- 2
        C=DAT1 S
        C=C&A S
        ?C#0 S
	GOYES GN00
        C=DAT1 S
        C=C!A S
        DAT1=C S
        D0=D0- 5
        CD1EX A
        D1=C A
        DAT0=C A
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        C=DAT1 S
        C=C!A S
        DAT1=C S
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        C=DAT1 S
        A=-A-1 S
        C=C&A S
        DAT1=C S
        D0=D0- 4
        A=A-1 B
        DAT0=A B
        RTN
GN00    LCHEX #07
        ?C<A B
	GOYES GN01
GN03    D0=D0- 9
        C=0 A
        DAT0=C 4
        A=-A-1 S
GN09    D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        C=DAT1 S
        C=C&A S
        DAT1=C S
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        C=DAT1 S
        C=C&A S
        DAT1=C S
        RTN
GN01    LCHEX #0D
        ?C<A B
	GOYES GN02
        ST=1 3
        ST=1 4
        GOSUB GN03
        LCHEX #07000
        D0=D0- 3
        A=DAT0 X
        DAT0=C X
        C=A X
        CSR A
        CD0EX A
        D=C A
        CD0EX A
        GOSUB SH99
        C=0 A
        P= 0
        LCHEX #FF
GN13    D=C A
        GOSUB BPR
        C=D A
        P= 1
        C=C-1 P
        GONC GN13
        P= 0
        LCHEX #0F
GN18    D=C A
        GOSUB BPR
        C=D A
        P= 1
        C=C+1 P
        GONC GN18
        P= 0
        RTN
GN02    A=-A-1 S
        C=DAT1 S
        C=C&A S
        DAT1=C S
        D1=D1- 16
        D1=D1- 16
        D1=D1- 2
        C=DAT1 S
        C=C&A S
        DAT1=C S
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        GOSUB GN09
        AD0EX A
        A=A+1 A
        R2=A W
        AD0EX A
        B=A A
        D0=D0- 8
        C=DAT0 B
        D0=(2) #5
        GOSUB GETLV
        D0=D0+ 11
        A=0 A
        A=DAT0 B
        ?A#0 B
	GOYES GN04
GN05    A=R2 W
        D0=A A
        D0=D0- 10
        C=0 A
        DAT0=C 4
        RTN
GN04    D0=D0+ 4
        A=A-1 A
        ACEX A
        D=C A
        C=C+C A
        C=C+C A
        AD0EX A
        A=A+C A
        AD0EX A
        C=DAT0 B
GN11    ?B<C B
	GOYES GN06
        C=C+CON B,6
        ?B>C B
	GOYES GN05
        C=C-CON B,6
GN08    B=C A
        D0=D0- 2
        C=DAT0 B
        ?C>A B
	GOYES GN07
        C=C+CON B,8
        ?C<A B
	GOYES GN05
        C=D A
        C=C+1 A
        GOSUB RMVENM
        ST=1 3
        ST=0 4
        GOTO GN05
GN07    D=D-1 A
        GOC GN05
        D0=D0- 2
        C=DAT0 B
        ?B=C B
	GOYES GN08
GN12    GOTO GN05
GN06    ASL A
        ASL A
        A=C B
GN10    D=D-1 A
        GOC GN12
        D0=D0- 4
        C=DAT0 B
        ?A=C B
	GOYES GN10
        ASR A
        ASR A
        GOTO GN11

GUNTWO  LCHEX #3E
        ?C>A B
	GOYES GN14
        D0=D0+ 4
        C=DAT0 A
        D0=D0+ 5
        D1=C A
        C=DAT0 S
        D0=D0- 9
        C=-C-1 S
GN15    A=DAT1 S
        A=A&C S
        DAT1=A S
        D1=D1- 16
        D1=D1- 16
        D1=D1- 2
        A=DAT1 S
        A=A&C S
        DAT1=A S
        C=0 A
        DAT0=C A
        RTNCC
GN14    D0=D0+ 4
        C=DAT0 A
        D0=D0+ 5
        D1=C A
        C=DAT0 S
        D1=D1+ 16
        D1=D1+ 16
        D1=D1+ 2
        A=DAT1 S
        A=A&C S
        ?A#0 S
	GOYES GN16
        A=DAT1 S
        A=A!C S
        DAT1=A S
        D0=D0- 5
        CD1EX A
        D1=C A
        DAT0=C A
        A=A+1 B
        D0=D0- 4
        DAT0=A B
        D1=D1- 16
        D1=D1- 16
        D1=D1- 2
        A=DAT1 S
        A=A!C S
        DAT1=A S
        C=-C-1 S
        D1=D1- 16
        D1=D1- 16
        D1=D1- 2
        A=DAT1 S
        A=A&C S
        DAT1=A S
        RTNCC
GN16    D0=D0- 9
        LCHEX #39
        ?C>A B
	GOYES GN17
        ASR A
        ASR A
        C=A A
        ?B>C B
	GOYES GN17
        B=B+CON B,8
        ?B<C B
	GOYES GN17
*       ( MYSHIP IS SHOT )
        GOTO ENDMY
GN17    C=-C-1 S
        A=DAT1 S
        A=A&C S
        DAT1=A S
        D1=D1- 16
        D1=D1- 16
        D1=D1- 2
        GOTO GN15

ENDMY   C=RSTK A
        GOSUB GN17
        C=0 A
        P= 0
        LCHEX #F
ENDM1   D=C A
        GOSUB BPR
        C=D A
        P= 1
        C=C+1 P
        GONC ENDM1
        P= 0
        ST=1 2
        GOSUB MYSHIP
        P= 0
        ST=0 2
        GOSUB MYSHIP
        D0=(2) #1
        GOSUBL GETLV
        D0=D0+ 10
        A=DAT0 P
        A=A-1 P
        GONC ENDM0
        GOLONG ENDGAME
ENDM0   DAT0=A P
        GOTO VISHIP

ENDLEV  C=RSTK A
        C=RSTK A
        LCHEX #48
        GOSUBL BPR
        LCHEX #58
        GOSUBL BPR
        LCHEX #B8
        GOSUBL BPR
        LCHEX #44
        GOSUBL BPR
        D0=(2) #7
        GOSUBL GETLV
        D0=D0+ 13
        A=0 A
        A=DAT0 X
        C=A A
        CSRB.F A
        CSRB.F A
        A=A-C A
        DAT0=A X
        D0=D0- 3
        DAT0=A X
        D0=(2) #5
        GOSUBL GETLV
        D0=D0+ 10
        AD0EX A
        AD1EX A
        D0=(2) #6
        GOSUBL GETLV
        D0=D0+ 10
        LCHEX #000C3
        GOSBVL =MOVEDOWN
        GOSUBL MKLCD
        D0=(2) #1
        GOSUBL GETLV
        D0=D0+ 10
        C=0 W
        C=DAT0 X
        DAT0=C W
        D0=D0+ 16
        LCHEX #00C
        DAT0=C B
        D0=D0- 14
        C=0 A
        P= 9
END1    D0=D0+ 16
        DAT0=C W
        P=P+1
        GONC END1
        D0=D0+ 16
        DAT0=C 8
        LCHEX #06000
END2    C=C-1 A
        GONC END2
        GOSUB VISCORE
        GOSUB VIHIGH
        GOSUB VISHIP
        GOLONG ST00

CTODEC  A=0 W
        A=C A
        GOSBVL =HXDCW
        SETHEX
        RTN

VISCORE D0=(5) =DSKTOP_gx
        C=DAT0 A
        D0=C A
        C=DAT0 A
        D0=C A
        D0=D0+ 10
        C=DAT0 A
        GOSUB CTODEC
        D0=(2) #8
        GOSUBL GETLV
        D0=D0+ 10
        AD0EX A
        AD1EX A
        D0=(2) #2
        GOSUBL GETLV
VIS2    D0=D0+ 16
        D0=D0+ 15
        AD0EX A
        D0=A A
        B=A A
        D=C A
        P= 15
        LCHEX #B
VIS1    P= 0
        C=0 A
        C=D P
        A=C A
        C=C+C A
        C=C+C A
        C=C+A A
        AD1EX A
        C=C+A A
        D1=C A
        P= 11
VIS0    C=DAT1 1
        DAT0=C 1
        D1=D1+ 1
        D0=D0+ 16
        D0=D0+ 16
        D0=D0+ 2
        P=P+1
        GONC VIS0
        DSR A
        D1=A A
        A=B A
        A=A-1 A
        B=A A
        D0=A A
        C=C+1 S
        GONC VIS1
        RTN

VIHIGH  D0=(2) #9
        GOSUBL GETLV
        D0=D0+ 10
        C=DAT0 A
        GOSUB CTODEC
        D0=(2) #8
        GOSUBL GETLV
        D0=D0+ 10
        AD0EX A
        AD1EX A
        D0=(2) #2
        GOSUBL GETLV
        D0=D0+ 14
        GOTO VIS2

VISHIP  D0=(2) #1
        GOSUBL GETLV
        D0=D0+ 10
        C=DAT0 P
        D0=(2) #8
        GOSUBL GETLV
        D0=D0+ 10
        AD0EX A
        AD1EX A
        D0=(2) #2
        GOSUBL GETLV
        D0=D0+ 16
        D0=D0+ 16
        D0=D0+ 16
        AD0EX A
        D0=A A
        B=A A
        D=C A
        P= 15
        LCHEX #F
        GOTO VIS1
        
BPR     B=C A            ( D,D0,D1 SAVED )
        AD1EX A
        D1=(5) #80851	( #706D2 )
        C=DAT1 B
        ?CBIT=0 #3
	GOYES BP3
        D1=A A
        RTN
BP3     D1=(5) #80642	( =ORghost )
        C=DAT1 X
        OUT=C
        D1=(5) #12E
        CSL A
        CSL A
        C=DAT1 B
        RSTK=C A
        C=0 B
        DAT1=C 1
        CSR A
        CSR A
        BCEX A
        CSL A
        P=C #2
        C=P #4
        BCEX X
BP2     OUT=C
        P=C #4
        ?CBIT=1 #B
	GOYES BP0
        CBIT=1 #B
        ?CBIT=1 #B
	GOYES BP1
BP0     CBIT=0 #B
        ?CBIT=1 #B
	GOYES BP1
BP1     DSLC W
        DSRC W
        P=P-1
        GONC BP1
        B=B+1 B
        GONC BP2
        P= 0
        D1=(5) #12E
        C=RSTK A
        DAT1=C 1
        D1=(5) #80642	( =ORghost )
        C=DAT1 X
        OUT=C
        D1=A A
        RTN
      ENDCODE
      TEN NDROP UNCOERCE
      ' ID Score ID>TAG
      $ "Copyright Mozgy , 1993"
      DISPSTATUS2 SetDA1Temp
   ; 
;


-- 
Mario Mikocevic (Mozgy)
lfsck error: FUBR !