From: mozgy@danielle.mozgy.hr (Mario Mikocevic Mozgy)
Newsgroups: comp.sys.hp48
Subject: line.s
Date: 18 Nov 1998 18:47:51 GMT
Organization: HiNet
Lines: 473
Message-ID: <slrn7565jd.ko.mozgy@danielle.mozgy.hr>
Reply-To: mario.mikocevic+news@sk.tel.hr
NNTP-Posting-Host: al8-p54-zg.tel.hr
Mime-Version: 1.0
Content-Type: text/plain; charset=US-ASCII
Content-Transfer-Encoding: 7bit
X-Trace: as102.tel.hr 911414871 26172 195.29.235.182 (18 Nov 1998 18:47:51 GMT)
X-Complaints-To: news@tel.hr
NNTP-Posting-Date: 18 Nov 1998 18:47:51 GMT
User-Agent: slrn/0.9.5.3 (UNIX)
Xref: republic.btigate.com comp.sys.hp48:18732

Well,
I appologize for all my abusive talk here before and I'll try
to be productive now.

Since I'm now digging through all my very old HP48 archives
(dated to 89 or 90) I'll be posting from time to time some
interesting ML code here. Here's first ->

oh, btw, if it is huge, complain loud, if it's uninteresting,
complain loud, if it's lousy and sloppy code definately complain.

*****************************************************************************
**	Equates
*****************************************************************************

ASSEMBLE

sNegDX		EQU	0
sNegDY		EQU	1

DRAW		EQU	0
ERASE		EQU	1

*****************************************************************************
**	Flags
*****************************************************************************

ASSEMBLE

** DRAW	ERASE
**   1	   x	drawing	line points
**   0	   1	erasing	line points
**   0	   0	toggling line points

*	SETFLAG	DRAW
*	SETFLAG	ERASE

	LISTM

*****************************************************************************
**	Macros
*****************************************************************************

ASSEMBLE

AorB	MACRO	$fs
	A=A!B	$1
AorB	ENDM

** watch out !!!
** this	macro uses C[fs] aswell
AxorB	MACRO	$fs
	C=A	$1
	A=A!B	$1
	C=C&B	$1
	C=-C-1	$1
	A=A&C	$1
AxorB	ENDM

Aand!B	MACRO	$fs
	B=-B-1	$1
	A=A&B	$1
	B=-B-1	$1
Aand!B	ENDM


If0	IF	DRAW

MkPoint	MACRO
	AorB	S
MkPoint	ENDM

If0	ELSE
If1	 IF	ERASE

MkPoint	MACRO
	Aand!B	S
MkPoint	ENDM

If1	 ELSE

MkPoint	MACRO
	AxorB	S
MkPoint	ENDM

If1	 ENDIF
If0	ENDIF

*****************************************************************************
**	Routines
*****************************************************************************

RPL
::
  CK3NOLASTWD
  CK&DISPATCH1
  # C55
  ::
    2HXSLIST?
    ROT
    2HXSLIST?

* 5: Graphic
* 4: # X1
* 3: # Y1
* 2: # X2
* 1: # Y2
	CODE

	GOSBVL	=SAVPTR

** making point	numbers	from range -524288,524287
** to 0,1048576	for easier comparison

	A=DAT1	A
	D0=A
	D0=D0+	5
	D1=D1+	5
	LC(5)	#80000
	A=DAT0	A			Y2
	A=A+C	A
	B=A	A
	R0=A.F	A
	A=DAT1	A
	D0=A
	D0=D0+	5
	D1=D1+	5
	A=DAT0	A			X2
	A=A+C	A
	R1=A.F	A
	A=DAT1	A
	D0=A
	D0=D0+	5
	D1=D1+	5
	A=DAT0	A			Y1
	A=A+C	A
	R2=A.F	A
	A=DAT1	A
	D0=A
	D0=D0+	5
	D1=D1+	5
** we'll save pointer to Graphic to D1
** for later use
	A=DAT1	A
	D1=A
	D1=D1+	10
	A=DAT0	A			X1
	A=A+C	A
	R3=A.F	A
	A=R2.F	A
	?A<B	A
	GOYES	+
	AR1EX.F A			swap points so	T1 is
	AR3EX.F A			above T2 for easier
	AR1EX.F A			clipping
	AR0EX.F A
	R2=A.F	A
+	?A>=C	A
	GOYES	++
** Y1 is negative
	A=R0.F	A
	?A>=C	A			If both Ys are	negative
	GOYES	+		 	we don't have anything
	GOTO	end!			to do,	so we quit

*****************************************************************
** here	we have	T1 point lying above of	Graphic	area
** and we have to calculate line position for new point
** on left Graphic boundary (NewX1,0)
** equations are:
**	NewY1 =	0
**	NewX1 =	X1 + ( ABS( Y1 ) * DX )	/ DY

+	A=R2.F	A
	A=-A	A
	A=A-C	A			A[A]: ABS( Y1 )
	C=R3.F	A
	B=C	A
	C=R1.F	A
	ST=0	sNegDX
	C=C-B	A			C[A]: DX
	GONC	+
	C=-C	A
	ST=1	sNegDX
+	GOSBVL	=MUL#			B[A]: ABS( Y1 )	* DX
	LC(5)	#80000
	CR2EX.F A			R2[A]:	0	(NewY1)
	A=R0.F	A
	C=A-C	A			C[A]: DY
** we don't have to pay	attention on carry here
** because we already have stated that A[A]: Y2	is
** bigger number than C[A]: Y1
	A=B	A
	GOSBVL	=IntDiv		 	C[A]: ABS( Y1 ) * DX /	DY
	?ST=0	sNegDX
	GOYES	+
	C=-C	A
+	A=R3.F	A
	C=C+A	A			C[A]: NewX1
	R3=C.F	A
	LC(5)	#80000
++	A=DAT1	A
	A=A+C	A
	A=A-1	A
	B=A	A
	A=R0.F	A
	?A<=B	A
	GOYES	++
** Y2 is below lower boundary
	A=R2.F	A
	?A<=B	A			If both Ys are	below
	GOYES	+			we don't have anything
	GOTO	end!			to do,	so we quit

*****************************************************************
** here	we have	T2 point lying below of	Graphic	area
** and we have to calculate line position for new point
** on bottom Graphic boundary (NewX2,MaxY)
** equations are:
**	NewY2 =	MaxY
**	NewX2 =	X2 - ( ( Y2 - MaxY ) * DX ) / DY

+	A=R0.F	A
	A=A-B	A			A[A]: Y2 - MaxY
	C=R3.F	A
	CBEX	A
	RSTK=C				save boundary to RSTK
	C=R1.F	A
	ST=0	sNegDX
	C=C-B	A			C[A]: DX
	GONC	+
	C=-C	A
	ST=1	sNegDX
+	GOSBVL	=MUL#			B[A]: (	Y2 - MaxY ) * DX
	C=RSTK
	CR0EX.F A			R0[A]:	MaxY
	A=R2.F	A
	C=C-A	A			C[A]: DY
** we don't have to pay	attention on carry here
** because we already have stated that A[A]: Y1	is
** bigger number than C[A]: Y2
	A=B	A
	GOSBVL	=IntDiv			C[A]: ( Y2 - MaxY ) * DX / DY
	?ST=0	sNegDX
	GOYES	+
	C=-C	A
+	A=R1.F	A
	C=A-C	A			C[A]: NewX2
	R1=C.F	A
	LC(5)	#80000
++	A=R1.F	A
	B=A	A
	A=R3.F	A
	?A<B	A
	GOYES	+
	AR0EX.F A			we will draw line from
	AR2EX.F A			left to right so switch
	AR0EX.F A			registers that	R3/R2 pair
	AR1EX.F A			holds leftmost	point
	R3=A.F	A
+	?A>=C	A
	GOYES	++
** X1 is negative
	A=R1.F	A
	?A>=C	A			If both Xs are	negative
	GOYES	+			we don't have anything
	GOTO	end!			to do,	so we quit

*****************************************************************
** here	we have	T1 point lying left of Graphic area
** and we have to calculate line position for new point
** on left Graphic boundary (0,NewY1)
** equations are:
**	NewX1 =	0
**	NewY1 =	Y1 + ( ABS( X1 ) * DY )	/ DX

+	A=R3.F	A
	A=-A	A
	A=A-C	A			A[A]: ABS( X1 )
	C=R2.F	A
	B=C	A
	C=R0.F	A
	ST=0	sNegDY
	C=C-B	A			C[A]: DY
	GONC	+
	C=-C	A
	ST=1	sNegDY
+	GOSBVL	=MUL#			B[A]: ABS( X1 )	* DY
	LC(5)	#80000
	CR3EX.F A			R3[A]:	0	(NewX1)
	A=R1.F	A
	C=A-C	A			C[A]: DX
** we don't have to pay	attention on carry here
** because we already have stated that A[A]: X2	is
** bigger number than C[A]: X1
	A=B	A
	GOSBVL	=IntDiv		 A[A]: ABS( X1 ) * DY /	DX
	?ST=0	sNegDY
	GOYES	+
	C=-C	A
+	A=R2.F	A
	C=C+A	A			C[A]: NewY1
	R2=C.F	A
	LC(5)	#80000
++	D1=D1+	5
	A=DAT1	A
	A=A+C	A
	A=A-1	A
	B=A	A
	A=R1.F	A
	?A<=B	A
	GOYES	++
** X2 is smaller than boundary
	A=R3.F	A
	?A<=B	A			If both Xs are	over right
	GOYES	+			we don't have anything
	GOTO	end!			to do,	so we quit

*****************************************************************
** here	we have	T2 point lying right of	Graphic	area
** and we have to calculate line position for new point
** on right Graphic boundary (MaxX,NewY2)
** equations are:
**	NewX2 =	MaxX
**	NewY2 =	Y2 - ( ( X2 - MaxX ) * DY ) / DX

+	A=R1.F	A
	A=A-B	A			A[A]: X2 - MaxX
	C=R2.F	A
	CBEX	A
	RSTK=C				save boundary to RSTK
	C=R0.F	A
	ST=0	sNegDY
	C=C-B	A			C[A]: DY
	GONC	+
	C=-C	A
	ST=1	sNegDY
+	GOSBVL	=MUL#			B[A]: (	X2 - MaxX ) * DY
	C=RSTK
	CR1EX.F A			R1[A]:	MaxX
	A=R3.F	A
	C=C-A	A			C[A]: DX
** we don't have to pay	attention on carry here
** because we already have stated that A[A]: X1	is
** bigger number than C[A]: X2
	A=B	A
	GOSBVL	=IntDiv		 A[A]: ( X2 - MaxX ) * DY / DX
	?ST=0	sNegDY
	GOYES	+
	C=-C	A
+	A=R0.F	A
	C=A-C	A			C[A]: NewY2
	R0=C.F	A
	LC(5)	#80000
++	A=R0.F	A
	B=A	A
	A=R2.F	A
	ST=0	sNegDY
	B=B-A	A			DY
	GONC	+
	B=-B	A
	ST=1	sNegDY
+	A=A-C	A
	R0=A.F	A			X1
	A=R3.F	A
	C=A-C	A
	CR1EX.F A			Y1
	C=C-A	A
	D=C	A			DX
	A=DAT1	A
	D1=D1+	5
	GOSBVL	=w->W
	AR0EX.F A
	ASRC
	B=A	S
	ASLC
	ASRB.F	A
	ASRB.F	A
	CD1EX
	C=C+A	A
	CD1EX
	C=B	A
	CR1EX.F A
	A=R0.F	A
	GOSBVL	=MUL#
	A=R1.F	A
	ABEX	A
	CD1EX
	C=C+A	A
	CD1EX
	A=R0.F	A
	LC(1)	3
	BSLC
	C=C&B	P
	BSRC
	B=0	S
	B=B+1	S
-	?C=0	P
	GOYES	+
	C=C-1	P
	B=B+B	S
	GONC	-
+	A=DAT1	S
	?ST=0	sNegDY
	GOYES	+
	A=-A	A
+	C=D	A
	C=C+B	A
	?C=0	A
	GOYES	end
	C=D	A
	?C<B	A
	GOYES	LineDY

* dx moving
LineDX	C=C-1	A
	D0=C
	B=B+B	A
	D=D+D	A
DXLoop	MkPoint
	C=C-B	A
	GONC	dxskip
	C=C+D	A
	DAT1=A	S
	CD1EX
	C=C+A	A
	CD1EX
	A=DAT1	S
dxskip	B=B+B	S
	GONC	dxloop
	B=B+1	S
	DAT1=A	S
	D1=D1+	1
	A=DAT1	S
dxloop	D0=D0-	1
	GONC	DXLoop
end	DAT1=A	S
end!	GOVLNG	=GETPTRLOOP

* dy moving
LineDY	C=B	A
	D0=C
	B=B+B	A
	D=D+D	A
DYLoop	MkPoint
	C=C-D	A
	GONC	dyloop
	C=C+B	A
	B=B+B	S
	GONC	dyloop
	B=B+1	S
	DAT1=A	S
	D1=D1+	1
	A=DAT1	S
	GONC	dyloop!
dyloop	DAT1=A	S
dyloop!	CD1EX
	C=C+A	A
	CD1EX
	A=DAT1	S
	D0=D0-	1
	GONC	DYLoop
	GOC	end!
	ENDCODE

  ;
;



-- 
Mario Mikocevic (Mozgy)
lfsck error: FUBR !
