Path: sam.via.ecp.fr!not-for-mail
From: "Jean-Yves Avenard" <avenar_j@epita.fr>
Newsgroups: hp48.programming
Subject: Re: rservation de la mmoire
Date: Mon, 7 Dec 1998 16:47:01 +1100
Organization: the Nimp Team
Lines: 269
Message-ID: <74fq63$fhh$1@sam.via.ecp.fr>
References: <1djeecf.133ah6t14bvu9uN@tntrasp18-23.abo.wanadoo.fr>
NNTP-Posting-Host: palrel3.hp.com
X-Server-Date: 7 Dec 1998 05:47:47 GMT
X-Priority: 3
X-MSMail-Priority: Normal
X-Newsreader: Microsoft Outlook Express 5.00.0810.800
X-MimeOLE: Produced By Microsoft MimeOLE V5.00.0810.800
Xref: sam.via.ecp.fr hp48.programming:805

Bon,

Il y a eu plein de reponses, mais aucune convenable a mon gout.

Donc, disons que tu veux reserver toutes la memoire de la 48 pour une chaine
de caractere.

Tout d'abord, tu vas calculer la memoire disponible.
Le point d'entree dans la ROM est =ROOM (#06806)

Cela va te renvoyer dans le champ A de C, la quantite de memoire disponible
(en quartet).
Donc tu fais (syntaxe HP)
    GOSBVL    =ROOM

Pour reserver une chaine de caractere, tu vas utiliser le point d'entree
=MAKE$N (#05B7D). Ca prend en parametre:
Dans le champ A de C, la quantite de quartets que tu veux avoir dans ta
chaine.

Bon, ecrire champ A de C, c'est trop long, donc a partir de maintenant, on
va utiliser la notation de Cyrille:
Ca = Champ A de C
Ab = Champ B de C.

Comme est code une chaine de caractere:
5 quartets : prologue - 5 quartets : taille - n quartets : chaine.

Comment marche MAKE$N.
Cela va allouer un segment de donnees dans la RAM des objets temporaires
(tout a la fin de cette zone).
La tete de la zone des objets temporaires est decrite dans le Voyage (qu'il
est imperatif de posseder), mais en voici un petit resume ici:
1 quartet : Drapeau disant si l'objet est utilise ou pas (utiliser par le
garbage)
n quartets : objet temporaire
5 quartets : taille du segment de donnees.

Ainsi, chaque objet dans la zone des objets temporaires utilise 6 quartets
dans la definition.

donc, pour reserver une chaine de caracteres il nous faut:
1 quartet pour le flag
5 quartet pour le prologue
5 quartets pour la taille de la chaine
n quartets pour n caracteres
5 quartets pour la taille de la zone de l'objet temporaire.

Soit un total de 16 quartets par STRING !!

Mais ce n'est pa fini. MAKE$N s'assure qu'il y a aussi 5 quartets de libre
pour pouvoir poser la chaine sur la pile RPN.
Donc si tu veux reserver une chaine de n caracteres, il faut etre certain
que (n*2 + 21) quartets sont disponibles en RAM.

Le code source pour reserver toute la memoire devient donc: (je ne ferai pas
de test pour lancer un GARBAGE collector etc.. il vaut mieux faire un
garbage systematique, sinon reserver toute la RAM n'a plus aucun sens).

::
  GARBAGE
  CODE
    GOSBVL    =SAVPTR        #0679B
    GOSBVL    =ROOM            #06806
    C=C-CON    A,16
    GONC    +
TFM
    GOSBVL    =GETPTR            #067D2
    GOSBVL    =DOMEMERR        #04FBB
+
    C=C-CON    A,5
    GOC    TFM
*
* Dans Ca, on a donc la taille maximale qu'on peut reserver pour une chaine
de caracteres.
*
    RSTK=C                    Je sauvegarde la taille de ma chaine, pour un
usage ulterieur
    GOSBVL    =MAKE$N
*
* R0a = Adresse de la chaine qu'on vient de reserver
* D0 = Adresse du premier quartet libre dans la chaine de caracteres (juste
apres les 5 quartets de taille)
*         on peut donc ecrire juste a cet endroit

* Maintenant, on va ecrire dans la chaine, la chaine classique: Hello Word

*
* Je vais utiliser la routine de copie, MOVEDOWN (#0670C), elle copie Ca
quartets pointes par D0
* vers l'adresse memoire pointee par D1. Ici mon adresse de destination est
contenu dans D0,
* je vais donc mettre le contenu de D0 dans D1
*
    CD0EX
    D1=C

    GOSUB    Fin.Chaine
Debut.Chaine
    NIBASC    \Hello World\
Fin.Chaine
    C=RSTK        On recupere l'adresse de mes datas. (le gosub a sauvegarde
ca dans la RSTK)
    D0=C            Adresse d'origine pour la copie

    C=RSTK    Contient la taille de ma chaine de caracteres que j'ai reserve
plus haut.
    D=C    A        On le met dans le registre D.

* Calculons la taille des donnees a copier:
    LC(5)    (Fin.Chaine)-(Debut.Chaine)
* A t'on assez de place pour le copier ?
    D=D-C    A
    GONC    +        On aurai pu faire un GOC TFM, mais il se peut que le
saut soit trop court
    GOTO    TFM        Error Insufficient Memory
+

* MOVEDOWN prend les arguments suivant:
* D0 adresse origine
* D1 adresse de destination (les deux zones ne doivent pas se recouvrir,
sinon faut utiliser MOVEUP)
* Ca nombre de quartets a copier
    GOSBVL    =MOVEDOWN
* Au retour D0 et D1 on ete incremente du nombre de quartets copies, donc D1
pointe
* juste apres le dernier caractere copie.

* Deuxieme operation, la plus delicate. J'ai donc reserve toute la memoire
* pour copier une chaine de caracteres.
* Maintenant, je vais "de-reserver" tout ce que je n'ai pas utiliser.
* On va utiliser le point d'entree Shrink$ pour cela (#16671), au passage la
routine FREE
* donnee par HPREG, est EXACTEMENT celle que j'ai utilise dans le
StringWriter il y a
* 8 ans, que on savait pas que Shrink$ existait. Elle est ete codee par
Christian Bourgeois

* Shrink$ prend les arguments suivant:
* R0 = Adresse de la chaine de caractere (ou n'importe quel type d'objet
ayant la meme
* structure qu'une string.
* D0 = Nouvelle adresse de fin

* Dans notre exemple, D1 pointe juste apres le dernier caractere. C'est donc
aussi l'adresse
* de notre nouvelle adresse de fin.
* Il faut donc que je mette le contenu de D1 dans D0 (utilise par Shrink$)

    CD1EX
    D0=C

* On de-reserve
    GOSBVL    =Shrink$

* On pose la chaine sur la pile
    GOSBVL    =GETPTR        Restaure les registres
    D1=D1-    5
    D=D-1    A        Il y a assez de place sur la pile RPN, car MAKE$N s'en
est assure.
    A=R0                Pose l'objet sur la pile RPN
    DAT1=A    A
    A=DAT0    A
    D0=D0+    5
    PC(A)            Retour RPL (On aurai pu faire un appel en ROM, mais
c'est moins "pedagogique"

ENDCODE
;

Et voila !!! (bon ca devrai marcher, mais je fait ca en temps reel, pas
teste.

On aura dans ce court exemple:
Reserver toute la RAM, copie des donnees dedans, de-reserver la chaine
creer, la poser sur la pile.

C'est pas beau ca ??

Bon, allez, pour que les mordu du MASD ne pense pas que j'ai vendu mon ame
au diable,
on va se le refaire a la syntaxe MASD, mais sans les commentaires, j'ai pas
le temps.
On est en mode ASSEMBLEUR par defaut.

"!NO CODE
!RPL
::
    GARBAGE
     CODE
    SAVE %Ou GOSBVL =SAVPTR pour les ferus de la syntaxe HP quand meme
    GOSBVL =ROOM
    C-16.A SKIPNC { *TFM LOAD GOSBVL =DOMEMERR }
     C-5.A GOC TFM
    RSTK=C
    RES.STR CD0EX D1=C

    SKUB { *Debut.Chaine cHello Worldc *Fin.Chaine } C=RSTK D0=C
    C=RSTK D=C.A
    LC(5) Fin.Chaine-Debut.Chaine
    D-C.A GOTOC TFM
    COPY<-

    CD1EX D0=C
    GOSBVL =Shrink$
    LOAD
    D1-5 D-1.A
    A=R0.W DAT1=A.A
    RPL
ENDCODE
;
@"

Comme vous pouvez le notez, j'emploi la notation MASD de facon a mettre sur
une ligne
une fonction. Et non pas une instruction.
Cela me permet de mieux organiser le code, et de plus facilement me relire.

Le MASD donne plein de macro-instruction pour toutes les commandes les plus
utilisee:
SAVE   = GOSBVL =SAVPTR
LOAD = GOSBVL =GETPTR
RES.STR = GOSBVL =MAKE$N
LOADRPL = GOSBVL =GETPTRLOOP
RPL = A=DAT0.A D0=D0+5 PC=(A)

etc...

A bientot pour de nouvelles aventures.

Jean-Yves

F.H. Gilbert <gilbz@wanadoo.fr> wrote in message
news:1djeecf.133ah6t14bvu9uN@tntrasp18-23.abo.wanadoo.fr...
>Salut,
>
>j'ai un programme qui doit poser une chane sur la pile, mais celle-ci
>est de longueur variable, selon les paramtres d'entre du code.
>
>Comme je ne peux pas dterminer la taille requise de la chane  poser,
>et comme je ne veux pas prendre une valeur "par dfaut" qui me semble
>problmatique (et si le code tourne sur une G qui a assez de place pour
>la chane, mais pas assez pour la valeur par dfaut?).
>
>J'ai donc un code qui rserve toute la mmoire disponible, mais je ne
>sais pas comment cela fonctionne. Je peux faire un appel  un
>sous-programme qui me renvoie la quantit de quartets disponibles, et
>ensuite je les rserve tous; mais quand je pose ma chane sur la pile,
>et que je modifie la taille de l'objet pour qu'elle corresponde  la
>taille relle de la chane, la HP ragit comme si toute la mmoire (sauf
>8-6 Ko) tait rserve. Faire un "Garbage collector" ne semble rien y
>changer de tout.
>
>La quantit d'information disponible est trs faible; faut-il que je me
>tourne ves les livres en anglais? On m'a parl de livres en franais,
>mais ils ne sont plus disponibles (pas mme  Maubert...). Depuis une
>semaine, malgr la lecture intgrale de RPLMAN.DOC, SASM.DOC et d'une
>dizaine d'autres, je n'ai toujours pas trouv la description dtaille
>de l'objet "Library".
>
>Quels livres (anglais, puisque les franais ne semblent plus
>disponibles) me conseillez-vous?
>
>-Gilb-
>00 E2 22 76 58 1F 72 BA  EA 94 78 F3 A2 63 E0 94



