%%HP: T(3)A(R)F(.);
\<< CLLCD

\-> x a b n
    \<< x INDEP STEQ b a - n / 
        \-> h
        \<< a b XRNG 'a+I*h' 'I' 0 n 1 SEQ   @ Generate a list of the x-values
            DUP 1 \<< RCEQ x ROT 2 \->LIST | \->NUM \>> DOLIST @ and of the function values
            DUP TAIL \GSLIST h *             @ Calculate the Rh sum
            SWAP REVLIST TAIL \GSLIST h *    @ Calculate the LH sum
            SWAP DUP2 + 2 /                  @ Trapezoidal sum (TR)=(RH+LH)/2
            "Trap" \->TAG ROT
            "Left"   \->TAG ROT
            "Right"  \->TAG ROT
            4 ROLL DUP TAIL                   
            SWAP REVLIST TAIL REVLIST 
            ADD 2 /                          @ Generate a list of the x-values at the midpoints
            1 \<< RCEQ 'PPAR' 3 GET ROT 2 \->LIST | \->NUM \>> DOLIST @ and of the function values
            \GSLIST h * DUP                  @ Calculate the midpoint sum (MP)
            "Mid" \->TAG 
            SWAP 2 * 3 PICK DTAG + 3 /       @ Simpson's sum = (2*MP+TR)/3
            "Simp's" \->TAG
        \>>
    \>>
\>>