From: GLAUDE DAVID <dglaude@is1.vub.ac.be>
Subject:  v06i014:  showgrb_gd - Grob Viewer v1.0, Part01/01
Newsgroups: comp.sources.hp48
Followup-To: comp.sys.hp48
Approved: spell@seq.uncwil.edu

Checksum:  797674624 (verify with brik -cv)
Submitted-by: GLAUDE DAVID <dglaude@is1.vub.ac.be>
Posting-number: Volume 6, Issue 14
Archive-name: showgrb_gd/part01


BEGIN_DOC showgrob.doc
        Hello, HP48 users
( Q: is there any women in this mail server ???? ]

                I am glad to give you the first SYS-RPL
        application I wroted for a past examination. !!!
        It is a simple Grob Viewer with a scrolling capability
        that do not destroy PICT but work a bit the same as a
        "PICT STO GRAPH".

        Keys are "explane" in the source I give you below.
        Compiled version is given to save time to you.

        Mail me any comment or question.

        *******************************************
        ;-)     English is not my best skill    ;-)
        *******************************************
END_DOC


-----------------------------------------------------------------------
SOURCE FOR TOOLS :

BEGIN_SRC showgrob.m
OU SHOWGROB
LL SHOWGROB.LR
SU XR
SE ENTRIES.O
SE ENTRIADD.O
RE SHOWGROB.O
END_SRC

BEGIN_SRC entriadd.a
*
* Missing in entries.a
*
=Restore16 EQU #0E05B *
=Save16    EQU #0E047 *
END_SRC

BEGIN_SRC showgrob.s
* ShowGrob first distributed version.
* by Glu ( Glaude David )
* usage : one grob on first level !!!
* key   : arrow                 to scroll
*         shited arrow          to go to extremity
*         on                    to quit
*         next                  to see copyright message
*---------------------------------------------------------
*
* Include the header file KEYDEFS.H, which defines words
* like kcUpArrow at physical key numbers.
*
INCLUDE KEYDEFS.H
*
* Include the eight characters needed for binary download
*
ASSEMBLE
        NIBASC  /HPHP48-D/
RPL
*
* Begin the secondary
*
::
  CK1NOLASTWD
  CK&DISPATCH1 # C
  ::
  RECLAIMDISP           ( *Claim the alpha display* )
  ClrDA1IsStat          ( *Temporarily disable clock* )
*                       ( *Try removing ClrDA1IsStat* )
  VERYSLOW
  TURNMENUOFF           ( *Turn off menu line* )
  ZEROZERO              ( UserGrob #0 #0 )
  ROT                   ( #0 #0 UserGrob )
  XYGROBDISP            (  )
*
  FALSE                 ( FALSE )
  { LAM Exit } BIND     ( *Bind POL exit flag* )
  ' NOP                 ( *No display action*  )
  ' ::                  ( *Hard key handler*   )
    kpNoShift #=casedrop
      ::
         kcUpArrow    ?CaseKeyDef
                          :: TakeOver SCROLLUP ;
         kcLeftArrow  ?CaseKeyDef
                          :: TakeOver SCROLLLEFT ;
         kcDownArrow  ?CaseKeyDef
                          :: TakeOver SCROLLDOWN ;
         kcRightArrow ?CaseKeyDef
                          :: TakeOver SCROLLRIGHT ;
         kcNextRow    ?CaseKeyDef
                          :: TakeOver Save16
                             "ShowGrob By Glu. 1992"
                             DISPROW1*
                             "dglaude@is1.vub.ac.be"
                             DISPROW2*  ERRBEEP
                             VERYVERYSLOW Restore16 ;
         kcOn         ?CaseKeyDef
                          :: TakeOver
                             TRUE ' LAM Exit STO ;
         kcRightShift   #=casedrpfls
         DROP 'DoBadKeyT
      ;
    kpRightShift #=casedrop
      ::
         kcUpArrow    ?CaseKeyDef
                          :: TakeOver JUMPTOP ;
         kcLeftArrow  ?CaseKeyDef
                          :: TakeOver JUMPLEFT ;
         kcDownArrow  ?CaseKeyDef
                          :: TakeOver JUMPBOT ;
         kcRightArrow ?CaseKeyDef
                          :: TakeOver JUMPRIGHT ;
         kcRightShift #=casedrpfls
         DROP 'DoBadKeyT
      ;
    2DROP 'DoBadKeyT
  ;
  TrueTrue              ( *Key control flags* )
  NULL{}                ( *No softkeys here*  )
  ONEFALSE              ( *1st row, no suspend* )
  ' LAM Exit            ( *App exit condition* )
  ' ERRJMP              ( *Error handler* )
  ParOuterLoop          ( *Run the ParOuterLoop* )
  TURNMENUON            ( *Restore menu row* )
  RECLAIMDISP           ( *Resize and clear display* )
  ClrDAsOK              ( *Redraw display* )
  ;
;
END_SRC
-----------------------------------------------------------------

BEGIN_RDME showgrob.rdm
I hope source will help you to build aplication with TOOLS from HP.
This is just a transformation of some of the exemples from TOOLS
 but I think that the result is more usefull that these demo.
I do not revendic any copyright .... Not even the idee is new !!!
See TOOLS documentation for right copyright.
END_RDME

--
You can call me Glu.  To find me on IRC : /who dglaude*
 If I am there ...  /msg Glu Hello Glu ... I am a HP48 user/programmer.
 I will answer you as fast as possible.
e-mail : dglaude@is1.vub.ac.be
