From: wndalouise@aol.com (WndaLouise)
Newsgroups: comp.sys.hp48
Subject: Re: Display mode problem
Date: 24 Feb 1998 20:48:29 GMT
Lines: 312
Message-ID: <19980224204800.PAA19917@ladder02.news.aol.com>
NNTP-Posting-Host: ladder02.news.aol.com
X-Admin: news@aol.com
Organization: AOL http://www.aol.com
References: <34F2E990.5F0F@antispam.grm.hia.no>
Xref: republic.btigate.com comp.sys.hp48:7159

ASN means Assign...!!! you are correct...
it's found in the semi-hidden menu directory that is found when you hit the
left/purple-key then the CST-key, then the KEYS-menukey.

i'm not sure what you mean by list of assignments...???
you get to make up your own list...!!!

here's a directory with a few programs on it to help you navigate around the
USERKEYS which, by the way, are one of the most powerful and useful features on
the 48...!!!...essentially allowing you to create your own calculator...!!!

------------------:

UserKey Examiner

UserKey Examiner is designed to allow you to examine all your UserKey
Assignments, and then either keep selected assignments, delete them, add new
ones, modify existing assignments or save assignments in a separate list for
later examination.

To Operate:
Simply hit U.Ks? and wait while the UserKey list is Recalled.
A series of beeps will sound when the list is ready.
A Custom Menu will appear- revealing the 7 choices that you can select.
The Custom Menu is designed for RightHanded people, so you might want to switch
that around if you'd like...

The Menu Items are...from right to left:

OK    Allow that UserKey assignment to remain unchanged.
DEL   Remove that UserKey assignment.
ADD   Add a new UserKey assingment.
SAVE  Save a UserKey assignment to a separate list to examine later.
MODF  Modify a UserKey assignment or the key it's attached to.
BACK  Move backward through the list.

NXT ClEAR Stop the program and remove the CST menu.

When you're Adding or Modifying a UserKey assignment, 
An INFORM screen is brought up:
:::::::::::: MODIFY USERKEY ::::::::::
KEY #    95.1
ACTION   ->LIST

Use the usual INFORM proceedures to change the variables and hit OK to enter
your UserKey assignment.

Curiously-- If you add a UserKey 'out-of-sequence'... 
When the list is compiled, they'll all be arranged in their proper order.

The Program will then automatically terminate when you pass Key Position 95.6,
the last Key [+].

The Stack at the end will be:
3:                        Saved: { }
2: { S Action Key# Action Key# ... }
1:                           STOKEYS

To store the key assignments, hit EVAL.
To save the key assignment list somewhere else, hit the DROP key, 
and save the list as you would like.

The Saved list consists of those key assignments that you designated with the
SAVE key.  These would be keys that you might want to save somewhere else,
examine or modify and reinstall, or examine and delete.

Also Included:
The Usrz? program allows you to examine the UserKey assignments for a specific
isolated key. 
To Operate; hit Usrz?, 
Then when the prompt appears, hit the Key you'd like to examine.
OutPut will consist of either all the key assignments or a notification that
the selected key has no assignments.
Empty lists indicate that that key combination has no assignment.

Sample OutPut for Usrz?:
6:   36: OBJ->
5:    <-: OVER
4:     ->: ROT
3:     a: PICK
2:    a<-: { }
1:    a->: { }

The Asn program allows you to assign an Object to a UserKey as painlessly as
imaginable...??? 
Just load an object onto the stack, hit Asn, wait for the prompt, then hit the
UserKey Combination for the assignment you want.
So that if you want to assign this Toggle program to the Alpha level of the +/-
key, do this:
Load the program onto the stack.
1: << DUP FS? << CF >> << SF >> IFTE >>

Then hit Asn.
The Prompt comes up; Assign UserKey

Hit the Alpha Key ( to the left of the 7 key )
Hit the +/- key.
And you're done.

To use the program:
Put the number of a flag on the stack.
Such as:
1:   -40
Which controls whether or not the Time and Date are displayed.
Then hit the Amethyst Left Key, 
Then the Alpha Key, 
Then the Alpha Key again, 
Then the +/- Key, 
And the -40 Flag will be Toggled.
If the Time & Date were on, they're now off, 
And if they were off, they're now on.

The Other Programs that were included:

Put is just like PUT, except that it inserts the Object after the designated
Object that PUT would normally replace.

~Sub is just like SUB, except that it's the exact opposite.

Tags takes a list ( on 1: ) of Strings or any other objects, and assigns them
as TAGs to the other objects on the stack.

Bep takes a number such as 1, 2 or 3 and makes a Bep sound.

Blink Blinks the display and makes a bep sound.

The UserKeys Directory:

        Ukyz
     # 66C2h
        2237

---snip off the portions below and paste onto a clean text document---

%%HP: T(3)A(D)F(.);
DIR
  U\183Ks?
    \<< RCLKEYS DUP
SIZE 1 - 1 3
      START 2 Bep
      NEXT 0 {
"MODIFY USERKEY" {
"KEY #" "ACTION" }
{ } { 11.6
"Do This" } } { }
RCLF 2 \-> k z t a s
f i
      \<< -40 CF { {
"BACK"
        \<< 6 CONT
        \>> } {
"MODF"
        \<< 5 CONT
        \>> } {
"SAVE"
        \<< 4 CONT
        \>> } { "ADD"
        \<< 3 CONT
        \>> } { "DEL"
        \<< 2 CONT
        \>> } { "OK"
        \<< 1 CONT
        \>> } {
"CLEAR"
        \<< 2 MENU
'CST' PURGE KILL
        \>> } } MENU
        WHILE i z \<=
        REPEAT
CLLCD k i DUP 1 +
SUB DUP 't' STO
OBJ\-> DROP DUP IP
SWAP FP 10 * " " {
"" "\<-" "\->" "\Ga" "\Ga\<-"
"\Ga\->" } ROT GET + +
1 DISP 3 DISP 3
FREEZE HALT \-> \pi
          \<<
            CASE \pi
1 ==
              THEN
'i' 2 STO+
              END \pi
2 ==
              THEN
k i DUP 1 + ~Sub
'k' STO 'z' 2 STO-
              END \pi
3 ==
              THEN
k i 2 + a OBJ\-> DROP
4 ROLL DROP
"ADD USERKEY" 4
ROLLD DUP INFORM
\<< REVLIST Put 'k'
STO 'i' 2 STO+ 'z'
2 STO+
\>>
\<< DROP2
\>> IFTE
              END \pi
4 ==
              THEN
's' t 1 \->LIST STO+
Bl\161nk 'i' 2 STO+
              END \pi
5 ==
              THEN
k i 1 + a OBJ\->
DROP2 t REVLIST DUP
INFORM
\<< OBJ\-> DROP 4 ROLLD
PUT i ROT PUT 'k'
STO
\>>
\<< DROP2
\>> IFTE
              END \pi
6 ==
              THEN
i 2 - DUP NOT
\<< DROP z
\>> IFT 'i' STO
              END
            END
          \>>
        END f STOF
s "Saved" \->TAG k {
STOKEYS } OBJ\-> DROP
2 MENU 'CST' PURGE
      \>>
    \>>
  Usrz?
    \<< CLLCD
"  Examine UserKey"
3 DISP
      DO
      UNTIL KEY
      END IP DUP
DUP 10 / DUP IP
SWAP FP 10 * SWAP 1
- ROT 50 <
      \<< 6 *
      \>>
      \<< 5 * 4 +
      \>> IFTE + PATH
# 87927d SYSEVAL
EVAL 'UserKeys' RCL
SWAP EVAL SWAP GET
DUP SIZE
      \<< OBJ\-> DROP 7
ROLL { "\<-" "\->" "\Ga"
"\Ga\<-" "\Ga\->" } + :&:
Tags EVAL
      \>>
      \<< DROP2
"   No Assignments"
5 DISP 1 WAIT
      \>> IFTE
    \>>
  Asn
    \<< CLLCD
"  ASSIGN USERKEY"
3 DISP RCLF SWAP
-40 CF 0 WAIT ASN
STOF
    \>>
  Put
    \<< 3 PICK SIZE \->
a b c z
      \<< a 1 b 1 -
SUB c + a b z SUB +
      \>>
    \>>
  ~Sub
    \<< ROT DUP SIZE
OVER 1 6 ROLL 1 -
SUB ROT 4 ROLL 1 +
4 ROLL SUB +
    \>>
  Tags
    \<< OBJ\-> \-> $
      \<< 1 $
        START $ 1 +
ROLL SWAP \->TAG $
ROLLD
        NEXT
      \>>
    \>>
  Bep
    \<< { { 20 15 .5
} { 100 20 .1 } {
2000 500 .02 } {
4000 1000 .005 } }
SWAP GET EVAL \-> a b
c
      \<< RCLF -56 CF
RAND a * b + c BEEP
STOF
      \>>
    \>>
  Bl\161nk
    \<< RCLF -56 CF
PICT RCL LCD\-> PICT
STO { # 0d # 0d }
PVIEW PICT NEG RAND
3000 * 500 + .07
BEEP TEXT PICT STO
STOF
    \>>
END
