From: wndalouise@aol.com (WndaLouise)
Newsgroups: comp.sys.hp48
Subject: StopThem...! StopTheHamstersFromScreaming!
Lines: 934
Message-ID: <1998062920194600.QAA04216@ladder01.news.aol.com>
NNTP-Posting-Host: ladder01.news.aol.com
X-Admin: news@aol.com
Date: 29 Jun 1998 20:19:46 GMT
Organization: AOL http://www.aol.com
Xref: republic.btigate.com comp.sys.hp48:12660

---or---

More BandWidth Noise from the tiny boxes of Wanda Louise...!!!

-----------------------------------------::

123456789a123456789b123456789c123456789d123456789e123456789f123456789

  .-.  .-..-..-..-..-..-..-.  .-..-.    .-.  .---. .---. .-..-.
  | |_.| || .` || '' | >  <  / / | |_. /   \ | |-< | |-<  >  / 
  `---'`-'`-'`-'`----`'-'`-`'-'  `---'`--^--'`-'`-'`-'`-' `-'  
    .---..-..-..-..-..-..-.  .  .-. .-.  .-..-..-..   .-.  
    `| |'| || .` | >  /  \ \/ \/ / /   \ | .` || | ) /   \ 
     `-' `-'`-'`-' `-'    `. ^ .' `--^--'`-'`-'`-'/ `--^--'
          .-.   .--..---,.-..-.  .---..---..-..-..---.
         /   \ ( -< | |  | || |  | |- | O || .` |`| |'
        `--^--'`---)`---'`-'`-'  `-'  `---'`-'`-' `-' 

-------------------------------------o
The Linux/Larry/Wanda Ascii Font
-------------------------------------o

Ascii Font Idea/Design from The Linux Corporation 
Which was then Adopted & Modified by Larry CS     lcs@zk3.dec.com

This latest (?) version;
AsciiF Directory by TinyWanda                  WndaLouise@aol.com
                                                        June 1998       

-------------------------------------o

This Font Design originally came to my attention when i saw it incorporated in
Larry CS's Signature file...

i then began to work up a program to generate it, But i got bogged down when
the approach that i was using proved to have certain inherently bad
features...!!!

Then at some point, i wrote to Larry and asked him if it would be OK if i
created the directory to generate the font...
--that i was then still struggling with--
...and when & if i got it working, i could use it in my own Signature File &
then also, Post it--- ???

...And he told me that he stole the idea from a logo for The Linux Corporation
that he saw...! (?)

From that; he worked up his own Alphabet and sent it to me, And i sent him my
version. Both versions had several Good solutions, and a few Awful solutions
for various Characters...
i don't think either of us has the version that Linux created...???
Consequently; i think it's safe to say, That this font exists in at least three
distinct versions and that this version is called The Wanda Font.

The Directory that i use to translate/encrypt plain text into the Wanda font is
not -specifically- customized for this particular font however, and it may, and
has the tools within it, that will allow anyone to substitute their own Ascii
font into those appropriate data objects...
...whether that end is to further modify this font, or to create an entirely
new font from scratch...!

-------------------------------o

Because apparently all Larry had to work with was the word LINUX,
And i created the font originally from just LARRY, 
And then after he sent me his whole alphabet, i modified my own set
considerably, Improving many of my own designs and many of his...
Its still in flux, As many of the letters still dont look Right...?!

Fortunately, The Directory includes tools to easily modify the characters.

Larry seems to think consistency is more important, And ive been starting from
legibility, And trying to force consistency on them from there...???

When you find a good set of letters that work together, i think this is the
best of all the Ascii ( Figlet ) Fonts...!!! (?)

For more Information & Ascii Font Conversions, Examine;
http://st-www.cs.uiuc.edu/users/chai/figlet.html

-------------------------------o

Larrys Version:  ( Late March 1998 )

A    B   C    D    E    F    G    H      I  J    K     L     M
.---..--..---..--. .---..---..---..-. .-..-.  .-..-.,-..-.   .-.-.-.
| | ||-< | |  | \ \| |- | |- | |'_| |=| || | ,| || . < | |__ | | | |
`-^-'`--'`---'`-'-'`---'`-'  `-'-/`-' `-'`-'`---'`-'`-'`----'`-'-'-'
N     O     P    Q    R     S    T    U     V     W      X     Y
.-..-..----..---..---..---. .---..---..-..-..-..-..-.-.-..-..-..-..-.
| .` || || || |-'| O ,| |-<  \ \ `| |'| || | \  / | | | | >  <  >  / 
`-'`-'`----'`-'  `-'\\`-'`-'`---' `-' `----'  `'  `-----''-'`-` `-'  
Z     1 2    3    4    5   6    7    8   9   0     !  @  #  $
.---, /..---,.---. ,--.,---,-.  .---..--..--..----..-.e  || .-|-.
 / /  || / /   -||'-| | \ \| /-.`-/ /`//.`/ /| || |`v' a=  = \|\ 
`---' --`---'`---'  `-'`--'`---' `-' `--'`-' `----' o    || `-|-'
%    ^  *   (   )  -   =   +  { } [  ]  : ; " ',. <    >    /   ?
o ,-,a  \|/ ,-,.-.     ___  #  /\ ,,--..    |||    __  __    .-.,--.
 / /  n -*-( (  ) )### --- ###{  }||  ||o o       / /  \ \  / / `// 
`-' o  d/|\ `-`'-'          #  \/ ``--''o /    /O `-`  '-' '-'   o  

-------------------------------o

My Version:  ( June 1998 )

        .-.  ..   //   .||.        o   ||   ,-,  .-.    . 
        |_|  ||  =+=  ( --   O//  \\       ( (    ) )  -*-
         o       //   `-..)  //O  O\<       `-`  '-'   ' `
 .                 .-.   --//   ..  .---.  .---.   ,--.  .---.
-+-   o  ==       / /   | o |  / |   ) /    > <   /_| |  | --'
 '   /       o   '-'    //--   |.|  /---'   >- '    `-'   ).) 
,-.    .---.   .-.    .-.          ..        ..   .--.   _. 
| /-.  `-/ /  ( o )  ( o )  o  o  / /   ==   \ \  '-,)  ( d 
`.o.'   /./   ( o )   `_/   o  /  \_\   ==   /_/    o    `-/
  .-.    .---.  .---,  .-..   .---.  .---.  .---,  .-. .-.  .-.
 /   \   | | <  | |    | | )  | |=   | |-   | | _  | '=' |  | |
`--^--'  `---'  `---'  `-'/   `---'  `-'    `-'-/  `-' '-'  `-'
  .-.  .-.,-.  .-.    .-.  .-.  .-..-.  .---.  .--.   .---.
 .| |  | . <   | |_.  |  \/  |  | .` |  | O |  | o )  | o |
`---'  `-'`-'  `---'  ` `    '  `-'`-'  `---'  `.|    `--\\
.---.    .--.  .---.  .-..-.  .-..-.  .-.  .  .-.  .-..-.  .-..-.
| |-<   ( -<   `| |'  | '' |   \  /    \ \/ \/ /    >  <    >  / 
`-'`-'  `---)   `-'   `----`    `'      `. ^ .'    '-'`-`   `-'  
.---.  .---  .-.    ---.   /\        o    .   .-.    .         
 / /   | |    \ \    | |  '/\'        \  { {  | |   } }  .^v.  
/---'  `---    `-`  ---'        ===       '   '-'    '    ^v   

-------------------------------o
The Linux/Wanda Directory
-------------------------------o

The Directory consists of:

Start     AutoConversion from Normal text to Linux font.
->End     Converts Preformated Normal text to Linux font.
Caps      Converts lowercase to Capitals within String.
Fix?      Finds Bad Characters and allows user to change them.
Sprat     'Separate' Custom version of Split.
Form      Converts Temporary Form to Formatted form.
Edit      Returns an Ascii Character for examination.
Make      Installs an Ascii Character.
View      Allows you to view the whole Alphabet.
Split     Split up a string into a list of string fragments.
Pos2      Like POS, except that returns all instances found.
.->?<-.   How wide will an Ascii rendering be?
Bep       Makes Bep sound.
Blink     Blinks screen and beps!
->a       List of Allowed Characters.
->B       List of lists of Ascii Characters, Line by line.
->g       List of Character widths.
CST       Custom Menu for Character modification.

-------------------------------o
How to Use the Programs
-------------------------------o


-------------------------------o
Start     

You'd use this for almost all applications of converting/encrypting Plain-Text
into Ascii-Text.

Input is:
2:         "PlainTextString"
1:     Desired/Allowed Width

Output is:
1:            "Ascii String"

The String for Input may have any characteristics at all...
That is; It may contain illegal characters, lowercase characters, trans-128
characters, no carriage returns, lots of carriage returns...
...and so on.
Hopefully, the filters will catch all the nasty bits and process them in some
acceptable way before the string is converted into the Ascii typeface.
One thing it does, is when it checks for illegal characters, if it finds one,
or more, the program will display the illegal character and ask you to replace
it with a legal one...

( Regretfully, it doesn't check to see if your replacement it legal, the
program expects that the god-like humanimals know what they are doing...! )

To enter the new character, simply type it in, or transfer the active screen to
the CHARS menu, to find & Echo the desired character.
Then hit ENTER.
Repeat as necessary to replace all illegal characters.

The Desired/Allowed Width; is the number of character-spaces that you would
like the converted text to fill...
For EepMail or Bulletin Board postings, stay within 65 or perhaps 70.

-------------------------------o
->End     

You can Feed ->End a String if it's all ready to go...
no illegal characters & all the carriage returns in the right places...

Input is:
1:            "FullyReadyPlainText" 

Output is:
1:                   "Ascii String"

-------------------------------o
Caps      

You may occasionally want to work a PlainText String through the steps by
yourself, rather than use 'Start' or '->End'.
One reason is that; You're expecting the plaintext to produce anomalous
problems, and you want to fix them as you go along...???

Caps converts all lowercase characters in a string to Capitals, 
while leaving all the other characters unchanged.

Input is:
1:          "String123"

Output is:
1:          "STRING123"

-------------------------------o
Fix?      

Fix? Checks all the characters in the string you provide it with, 
and compares them to the list of allowable characters '->a'.
It then makes a list of these characters, 
then asks you for replacements for them, 
then replaces them in the string,
to return a new string with no ( hopefully* ) illegal characters.

*Assuming that you're not feeding it illegal characters.
If you're not sure, run it through Fix? again.

Input is:
1:        "RawPlainTextString"

Output is:
1:           "LegalizedString"

-------------------------------o
Sprat     

Separate, Separates the words in a String from the String, Returning all the
individual words to a List.
Sort of.
It only looks for Spaces and CarriageReturns that might break words apart. 
If the break occurs at a CarriageReturn, the CR is left on the end of the Word,
But if the break occurs at a space, then the space is discarded.

Input is:
1:            "StringOfWords"

Output is:
1:    { "List" "Of" "Words" }

-------------------------------o
Form      

Form takes the list of words, determines how big each will be after it's
converted to the AsciiFont and inserts CarriageReturns so that no line in the
newly structured String is too long.

Input is:
2:                       { "List" "Of" "Words" }
1:      Desired/Allowed Width In CharacterSpaces

Output is:
1:                    "StringThatIsAllReadyToGo"

All that remains then, is to feed this string to '->End'.

This is the point where you might want to check to see if all the
CarriageReturns have been put in places that you would consider
appropriate...???
If not...! 
Then you'll have to insert new spaces and some of your own CarriageReturns, and
then put the whole thing through Sprat and Form again...???

Normally, this would only occur as a problem if the PlainText contains long
words or hyphenated words, and the Allowed Width is undesirably short...???

-------------------------------o
Edit      

Edit is intended to allow you to pull individual characters off the DataBase
and modify them to your unique tastes/scruples.

IMPORTANT NOTE:
For the purpose of clarity...!...that is, to allow you to view the
AsciiFontCharacter undistorted, Edit adds a Carriage Return to the first
CharacterSpace so that the String Delimiter '"' does not take up a space on the
first line...???
Consequently; there will be an additional line on the top of the viewed
AsciiFontCharacter...!
Just ignore it!

To Edit the returned AsciiFontCharacter, simply hit the VIEW key, and edit it
to your hearts content, then hit ENTER, and 'Make' to add the modified
Character back into the DataBase.

Input is:
1:             "A"    ( Any Character in the DataBase )

Output is:
2:             "A"
1:     "AsciiCode"

In the actual DataBase; '->B'-- Each Line of the Ascii Code is stored on it's
own List, but Edit and Make assemble them into or out-of this disassembled
format for your convenience.

-------------------------------o
Make      

Make allows you to store an AsciiFontCharacter.
Simply use some graph-paper to design the character of your choice, or use
'Edit' to bring up an old AsciiFontCharacter, then modify/create it on the
CommandLine, and return/put it on the stack.

Also; on 2:, you have to put the character that your AsciiFontCharacter
represents.

Input is:
2:                                "A"  ( PlainTextCharacter )
1: "AsciiFontCharacterRepresentation"

No Output.

The AsciiFontCharacterRepresentation should be of the form;
"
   .-.
  /   \
 `--^--'"
On the CommandLine, All lines must be the same length!

The AsciiCharacter may or may not have the first line consisting of only a
CarriageReturn. If it does, it will be removed before storing.

'Make' allows you to Enter Modified Characters, over-writing old Data, or to
Enter New Characters, which are added to the end of the Data String/Lists.
It may have some Aesthetic desirability to have them all arranged neatly, but
it doesn't matter if they're all mixed up.

'Make' contains a borderline -bug- which may allow you to enter a flawed
character structure...it's supposed to check to make sure that  you've included
enough lines, and that all the lines are the same length, but due to a -clever-
routine i use to check for the later, it will allow uneven line
lengths...IF...you try to enter three lines  of all different sizes, and
they're sum is evenly divisible by the first line length...! (?)

-------------------------------o
View     

View allows you to view the entire collection of AsciiFontCharacters.
The PlainText Character will appear on the top of the Screen,
Followed by it's place in '->a' and it's CHR(x) value,
Then the AsciiFontRepresentation.
Hit any key to advance.
This program is for viewing purposes only, and is very simple in it's execution
and abilities.

-------------------------------o
Split     

Splits up a String, very much like 'Sprat', except that you're allowed to
choose the Character that you want to use to break up the string.
The Selected Break Characters are then discarded.

Input is:
2:                          "String"
1:                               " "  ( Single Break Character )

Output is:
1:  { "List" "Of" "Broken" "Parts" }

-------------------------------o
Pos2      

Like POS, except that it returns a list of all the instances found.

Input is:
2:             { List } or "String"
1:             'Object' or "String"

Output is:
1:        { List of All Positions }

-------------------------------o
.->?<-.   

How wide will an Ascii rendering be?
Returns the number of characters that the PlainText will represent after it's
been converted to the AsciiFont.

Input is:
1:         "PlainTextString"

Output is:
1:                Size/Width

-------------------------------o
Bep    

Makes Bep sound.

Input may be:
1:    { r  t }

r = number of times the bep will occur
t = tone of bep. can be either 1,2,3,4 or 5

Or Input may be:
1:           t

In which case, only one bep will occur.

No Output ( except for the sound of the bep(s) )

-------------------------------o
Blink     Blinks screen and beps!

-------------------------------o
->a       ( alpha )

String of Allowed Characters.
The Format for this String is pretty freeform, except that the CarriageReturn
Character CHR(10) has to be the first Character of the String.

-------------------------------o
->B       ( beta )

List of lists of Ascii Characters, Line by line.
If you're going to create your own Ascii font, and replace these lists with
your own empty lists, and use Make to create new characters...
You can do so by filling this List with any number of sublists, Each of which
will represent one line of your AsciiFont, Each Sublist/Line will then consist
of any number of strings which represent one line of each character that '->a'
defines.

When you start off though, each sublist must begin with a String that contains
the CarriageReturn Character CHR(10).

Such that; if your new AsciiFont has 5 lines per each Character,
then the new ->B would have 5 sublists, each sublist, to begin with, has one
string, which consists of CHR(10). 

-------------------------------o
->g       ( gamma )

List of Character widths.

If you're creating a new gamma list for a new AsciiFont, the blank list would
consist of this; { 0 }
The zero meaning that the Mandatory CarriageReturn takes up no space.

-------------------------------o
CST       

Custom Menu for Character modification.
When your either designing or modifying an AsciiFontCharacter, you may want to
use this CustomMenu [CST] where all the allowed characters are displayed for
easy access.
If you decide to create your own font, then you'll probably have to retool this
Menu!

-------------------------------o



-------------------------------------------o
Linux/Larry/Wanda Directory Listing
-------------------------------------------o

Name:           AsciF
CheckSum:     # D814h
Size:          6226.5

%%HP: T(3)A(D)F(.);
DIR
  Start
    \<<
C$ 43 2:           "String"
1:       DesiredWidth
"" INPUT OBJ\-> \-> \x-
      \<< CLLCD \->\Ga
"e" POS NOT
        \<<
"RemovingLowerCase"
3 DISP Caps
        \>> IFT
"CheckingForBadChr\180s"
3 DISP Fix? DUP
"NoErrors!!!" ==
:: DROP IFT
"Fitting" 3 DISP
Sprat \x-
"Restructuring" 3
DISP Form
"ConvertingToAscii"
3 DISP \->End Bl\161nk
      \>>
    \>>
  \->End
    \<< \->\Gb SIZE
      \<<
        WHILE DUP
        REPEAT ""
SWAP 1 -
        END DROP
      \>> \-> $ \162 \Gr
      \<< "" \162 \Gr EVAL
1 $ SIZE
        FOR \pi \->\Ga $
\pi DUP SUB POS \-> e
          \<< \->\Gb OBJ\->
            WHILE
DUP
            REPEAT
DUP 2 + ROLL ROT e
GET + OVER 3 +
ROLLD 1 -
            END
DROP e 1 ==
            \<< + + +
\162 \Gr EVAL
            \>> IFT
          \>>
        NEXT DUP ""
==
        \<< \162 DROPN
        \>>
        \<< 2 \162
          START 10
CHR SWAP + +
          NEXT +
        \>> IFTE
      \>>
    \>>
  Caps
    \<< "" 1 3 PICK
SIZE
      FOR $ OVER $
DUP SUB DUP NUM DUP
DUP 97 \>= SWAP 122 \<=
AND
        \<< 32 - CHR
SWAP
        \>> IFT DROP
+
      NEXT SWAP
DROP
    \>>
  Fix?
    \<< { } 1 3 PICK
SIZE
      FOR $ OVER $
DUP SUB \->\Ga OVER POS
NOT
        \<< DUP2 POS
:: DROP :: + IFTE
        \>> :: DROP
IFTE
      NEXT DUP SIZE
DUP 1 + { 3 } + Bep
      \<< 1 OVER SIZE
        FOR \162 DUP \162
GET \-> \Ge
          \<< \162 \Ge
"Repl " \Ge " (" OVER
NUM ") With" + + +
+ { "" \Ga } INPUT 2
\->LIST PUT 3 Bep
          \>>
        NEXT 1 OVER
SIZE
        FOR \165 DUP \165
GET EVAL \-> \185 \178
          \<< SWAP
DUP \185 Pos2 SWAP 1 3
PICK SIZE
            FOR \163
OVER \163 GET \178 REPL
            NEXT 3
ROLLD DROP
          \>>
        NEXT DROP
      \>>
      \<< DROP
"NoErrors!!!"
      \>> IFTE
    \>>
  Sprat
    \<< DUP " " Pos2
OVER 10 CHR Pos2 +
SORT OVER SIZE + \->
\Ga \Gb
      \<< { } 1 1 \Gb
SIZE
        FOR \GD \Gb \GD
GET DUP \Ga OVER DUP
SUB " " ==
          \<< 1 -
          \>> IFT 4
ROLL \Ga 5 ROLL 4
ROLL SUB DUP SIZE
NOT
          \<< DROP
" "
          \>> IFT +
SWAP 1 +
        NEXT DROP
      \>>
    \>>
  Form
    \<< OVER SIZE 10
CHR \->\GD \->\Ga " " POS
GET \-> p q \x- \GD
      \<< "" 0 1 q
        FOR \|v 3
PICK \|v GET \183\<-?\->\183
OVER \x- POS \-> \185 \178 \179
          \<< DUP \GD \178
+ + DUP p \<=
            \<< 3
ROLLD \185 " " \=/ AND
              \<< " "
+
              \>> IFT
\185 + SWAP
            \>>
            \<< DROP2
\x- \185 + + \178
            \>> IFTE
\179
            \<< DROP
0
            \>> IFT
          \>>
        NEXT ROT
DROP2
      \>>
    \>>
  Edit
    \<< \->\Ga OVER POS
DUP
      \<< \->\Gb 1 "\<<" 4
ROLL + " GET \>>" +
OBJ\-> DOLIST OBJ\->
DUP \-> \Ge
        \<< 2
          FOR \pi 10
CHR \pi ROLLD -1
          STEP 3 \Ge
2 *
          START +
          NEXT 10
CHR SWAP +
        \>>
      \>>
      \<< DROP
"Ack!
NoSuchCharacter"
DOERR
      \>> IFTE
    \>>
  Make
    \<< DUP HEAD 10
CHR == :: TAIL IFT
DUP 10 CHR Split
DUP SIZE \->\Gb SIZE
DUP2 ==
      \<< DROP SWAP
DUP
        \<< SIZE
        \>> DOLIST
DUP DUP HEAD SWAP
\GSLIST 5 ROLL / ==
        \<< DROP SWAP
DROP \->\Ga 3 PICK POS
DUP
          \<< \->\GD OVER
4 PICK HEAD SIZE
PUT '\->\GD' STO \->\Gb 3
ROLLD "\<< " SWAP
" SWAP PUT \>>" + +
OBJ\-> 2 SWAP DOLIST
'\->\Gb' STO DROP
          \>>
          \<< DROP \->\GD
OVER HEAD SIZE +
'\->\GD' STO '\->\Ga' ROT
STO+ \->\Gb SWAP
            \<< +
            \>>
DOLIST '\->\Gb' STO
          \>> IFTE
        \>>
        \<< SWAP DROP
"UnEven Lines"
DOERR
        \>> IFTE
      \>>
      \<<
" LinesNeeded" 10
CHR + + SWAP
" Provided" + +
SWAP DROP DOERR
      \>> IFTE
    \>>
  View
    \<< CLLCD 1 \->\Ga
SIZE
      FOR $ \->\Ga $
DUP SUB DUP 10 CHR
DUP2 $ " / " + ROT
NUM + SWAP + + +
SWAP \->End + 1 DISP
        IFERR
          DO
          UNTIL KEY
          END DROP
        THEN
"Terminated!"
DOERR
        END
      NEXT
    \>>
  Split
    \<<
"2:          String
1:  BreakCharacter"
.2 WAIT KEY
      \<< DROP ""
INPUT OBJ\->
      \>>
      \<< DROP
      \>> IFTE \-> \|v
      \<< { } SWAP
        WHILE DUP \|v
POS DUP
        REPEAT OVER
1 3 PICK 1 - SUB
DUP "" \=/
          \<< 4 ROLL
SWAP + 3 ROLLD
          \>>
          \<< DROP
          \>> IFTE 1
+ OVER SIZE SUB
        END DROP
DUP "" \=/
        \<< +
        \>>
        \<< DROP
        \>> IFTE
      \>>
    \>>
  Pos2
    \<< { } \-> $ \162
      \<<
        WHILE DUP $
POS DUP
        REPEAT \162
SIZE
          \<< DUP '\162'
1 GET +
          \>>
          \<< DUP
          \>> IFTE
'\162' STO+ 1 + MAXR
\->NUM SUB
        END DROP2 \162
REVLIST
      \>>
    \>>
  \183\<-?\->\183
    \<< DUP DUP SIZE
\-> $ \162
      \<< 0 1 \162
        FOR \pi \->\GD \->\Ga
$ \pi \pi SUB POS GET +
        NEXT
      \>>
    \>>
  Bep
    \<< DUP TYPE 5 ==
      \<< EVAL
      \>>
      \<< 1 SWAP
      \>> IFTE \-> \Ge \GD
      \<< { { 20 15
.5 } { 100 20 .1 }
{ 2000 500 .02 } {
4000 1000 .005 } {
8000 10 .04 } } \GD
GET EVAL \-> a b c
        \<< RCLF -56
CF 1 \Ge
          START
RAND a * b + c BEEP
          NEXT STOF
        \>>
      \>>
    \>>
  Bl\161nk
    \<< RCLF -56 CF
PICT RCL LCD\-> PICT
STO { # 0h # 0h }
PVIEW 1 RAND 9 *
CEIL
      START PICT
NEG RAND 3000 * 500
+ .07 BEEP
      NEXT TEXT
PICT STO STOF
    \>>
  \->\Ga
C$ 70 
 !"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\\]^_`{|}~
  \->\Gb { { "
" "  "
".-." ".." " //"
" .||." "   " " o "
"||" " ,-," ".-. "
" . " " . " "  "
"  " "  " "  .-."
" --//" " .."
".---." ".---."
" ,--." ".---."
",-.  " ".---."
" .-. " " .-. " " "
" " " .. " "  "
" .. " ".--."
" _. " "  .-.  "
".---." ".---,"
".-.. " ".---."
".---." ".---,"
".-. .-." ".-."
"  .-." ".-.,-."
".-.  " ".-.  .-."
".-..-." ".---."
".--. " ".---."
".---. " " .--."
".---." ".-..-."
".-..-."
".-.  .  .-."
".-..-." ".-..-."
".---." ".---"
".-.  " "---."
" /\\ " "   " "o "
" . " ".-." "  . "
"    " } { "
" "  "
"|_|" "||" "=+="
"( -- " "O//" "\\\\ "
"  " "( ( " " ) )"
"-*-" "-+-" " o"
"==" "  " " / / "
"| o |" "/ |"
" ) / " " > < "
"/_| |" "| --'"
"| /-." "`-/ /"
"( o )" "( o )" "o"
"o" "/ / " "=="
" \\ \\" "'-,)"
"( d " " /   \\ "
"| | <" "| |  "
"| | )" "| |= "
"| |- " "| | _"
"| '=' |" "| |"
" .| |" "| . < "
"| |_." "|  \\/  |"
"| .` |" "| O |"
"| o )" "| o |"
"| |-< " "( -< "
"`| |'" "| '' |"
" \\  / "
" \\ \\/ \\/ / "
" >  < " " >  / "
" / / " "| | "
" \\ \\ " " | |"
"'/\\'" "   " " \\"
"{ {" "| |" " } }"
".^v." } { "
" "  "
" o " "  " "// "
"`-..)" "//O" "O\\<"
"  " " `-`" "'-' "
"' `" " ' " "/ "
"  " "o " "'-'  "
"//-- " "|.|"
"/---'" " >- '"
"  `-'" " ).) "
"`.o.'" " /./ "
"( o )" " `_/ " "o"
"/" "\\_\\ " "=="
" /_/" "  o "
" `-/" "`--^--'"
"`---'" "`---'"
"`-'/ " "`---'"
"`-'  " "`-'-/"
"`-' '-'" "`-'"
"`---'" "`-'`-'"
"`---'" "` `    '"
"`-'`-'" "`---'"
"`.|  " "`--\\\\"
"`-'`-'" "`---)"
" `-' " "`----`"
"  `'  "
"  `. ^ .'  "
"'-'`-`" " `-'  "
"/---'" "`---"
"  `-`" "---'"
"    " "===" "  "
" ' " "'-'" "  ' "
" ^v " } }
  \->\GD { 0 2 3 2 3 5
3 3 2 4 4 3 3 2 2 2
5 5 3 5 5 5 5 5 5 5
5 1 1 4 2 4 4 4 7 5
5 5 5 5 5 7 3 5 6 5
8 6 5 5 5 6 5 5 6 6
11 6 6 5 4 5 4 4 3
2 3 3 4 4 }
  CST { " " "." "_"
"-" "," "|" "/" "\\"
">" "<" "'" "`" "^"
"v" "o" "=" "+" "("
")" "O" "V" { "CR"
"
" } Make Edit }
END
